dev-python/flask-bootstrap: bump to 3.3.7.0

Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/2281

Signed-off-by: David Seifert <soap@gentoo.org>

dev-python/flask-bootstrap/flask-bootstrap-3.3.7.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="An extension that includes Bootstrap in your project, without boilerplate code"
+HOMEPAGE="https://pythonhosted.org/Flask-Bootstrap/"
+# PyPI tarballs don't include tests
+# https://github.com/mbr/flask-bootstrap/pull/134
+SRC_URI="https://github.com/mbr/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/dominate[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/visitor[${PYTHON_USEDEP}]
+	dev-python/wtforms[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/flask-appconfig[${PYTHON_USEDEP}]
+		dev-python/flask-debug[${PYTHON_USEDEP}]
+		dev-python/flask-nav[${PYTHON_USEDEP}]
+		dev-python/flask-wtf[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	sed -i "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# Skip one test which requires network access
+	py.test -k "not test_versions_match" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}