dev-python/qscintilla-python: 2.10.3 version bump, dropping qt4 support

Bug: https://bugs.gentoo.org/634970
Package-Manager: Portage-2.3.24, Repoman-2.3.6

dev-python/qscintilla-python/Manifest

@@ -1,2 +1,3 @@
 DIST QScintilla_gpl-2.10.1.tar.gz 2663446 BLAKE2B 720ce990b4e3dd65d47cd26b473bffc07240d76b2c10d393cba41331c6f160472d87b9b22985fd45b5b8064d5358b3b25f0decfe8759542a9c987381249bca42 SHA512 ea9b95ca371a8af9262493ab59ecaef77e1697ba21d1d594aab39e836917884fd829aa4f6c4e72cce60b0d3f40eac654157cc507d027945f0034881855123ccc
 DIST QScintilla_gpl-2.10.2.tar.gz 2665138 BLAKE2B 1c6349ea717997681e678cdfa6cc590a6a1cfbe652f2dd52d57fefff71229251c46cd4554b546d2e272deb7c3f970c44f657966ad08e45279813215a775c637d SHA512 755f486d62275acb5908262c4a50ad31dd9d8fca0501eb1eeec1aa2181872f8d16179b42f4213b207fd6b46fd8a72d25af7ce6c5cc10eabb363a92c0600ca972
+DIST QScintilla_gpl-2.10.3.tar.gz 2721287 BLAKE2B cc85eea17e563ae5f4a130d26ca88bec3e1a6cbff7bc0af096c63789384d03149105641d6324f53b37a2bd8ab4681a285ccb76e6063a06e5db30d070d3fd8219 SHA512 a1b9d6869797ec074e4e0727164804779792fb77b2230aae80e6d6b5fb3a3ff9d84e17d775d18ab74c97b78bac454511fd2cb49be1fa36f71d9097abf88045b6

dev-python/qscintilla-python/qscintilla-python-2.10.3.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit python-r1 qmake-utils
+
+MY_P=QScintilla_gpl-${PV/_pre/.dev}
+
+DESCRIPTION="Python bindings for Qscintilla"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/intro"
+SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/sip-4.19:=[${PYTHON_USEDEP}]
+	dev-python/PyQt5[gui,printsupport,widgets,${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	~x11-libs/qscintilla-${PV}:=
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}/Python
+
+src_configure() {
+	configuration() {
+		# Fix out-of-source build and installation of .sip files
+		ln -s "${S}"/sip || die
+
+		local myconf=(
+			"${PYTHON}"
+			"${S}"/configure.py
+			--pyqt=PyQt5
+			--qmake="$(qt5_get_bindir)"/qmake
+			--sip-incdir="$(python_get_includedir)"
+			$(usex debug '--debug --trace' '')
+			--verbose
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Run eqmake to respect toolchain, build flags, and prevent stripping
+		eqmake5 -recursive
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+}