dev-python/python-efl: version bump to 1.21.0.

- Enabled python3.7

Package-Manager: Portage[mgorny]-2.3.43.3
Closes: https://github.com/gentoo/gentoo/pull/9708

dev-python/python-efl/Manifest

@@ -1,2 +1,3 @@
 DIST python-efl-1.18.0.tar.xz 8927932 BLAKE2B c1b41e1316c78fc42cf21541aba386dce799f1ec26549dda8c547de4cf47870a100070bb442d21116ce956808bcf948eba96601343512ba61fb1fc472e2574be SHA512 c1fc8d4129c2ac61b367ad373ad676a60cf0aed4c9150104d7e81bf464c44a3a5ae555d2298bbf1bdf6a3d6ba3b7d934af390e36755a1516972db2675d920c2b
 DIST python-efl-1.20.0.tar.xz 8984492 BLAKE2B 526c530d7b8dad59d01cefcbb6cad2710cb46c3b62eb0b2746c3552c8c1ef42cc4691072fbbce16a8a3b6ea9d6b5651a3645ca739e569a0f4db3dd9988ddf2fa SHA512 93d8d6c990350074e203bf3632d92b5253f34f318b30357b05ab5ab73a9f6656d127ff0c1831af1bf7c736822b483c12754085e52103eb0e41362cc28db5651f
+DIST python-efl-1.21.0.tar.xz 9544352 BLAKE2B b49fc0e0d795a0334f647f414673fdaf3b086eda35f9e2d0e9e6a03d2cde572e6076eeb62c4f977b770a72e8f14d4ae536f46d0510b8753088d80e2dfc98e43f SHA512 23a8487b660e9885a1d43a4835c560edd8d27eeb9aa44f9e1878ac1d1acf9833fc62c14036fe0fe5e0bd1144cb993b0b67bcf42c78db8505ca1b8aad0715350f

dev-python/python-efl/python-efl-1.21.0.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4..7} )
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for Enlightenment Foundation Libraries"
+HOMEPAGE="https://phab.enlightenment.org/w/projects/python_bindings_for_efl/"
+SRC_URI="https://download.enlightenment.org/rel/bindings/python/${P}.tar.xz"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	=dev-libs/efl-1.21*
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-python/cython-0.28.4[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+"
+
+src_prepare() {
+	default
+
+	# Tries to download a file under /tmp
+	rm tests/ecore/test_09_file_download.py || die
+
+	# Tries to use that file which failed to download
+	rm tests/ecore/test_10_file_monitor.py || die
+
+	# Needs an active internet connetion
+	rm tests/ecore/test_11_con.py || die
+
+	# Test fails because of deleted files above
+	sed -i 's/>= 13/>= 10/g' tests/ecore/test_08_exe.py || die
+
+	# Make tests verbose
+	sed -i 's:verbosity=1:verbosity=3:' tests/00_run_all_tests.py || die
+}
+
+python_compile_all() {
+	if use doc ; then
+		# Point sphinx to right location with built sources
+		sed -i 's|"../build/"+d|"'"${BUILD_DIR}"'/lib"|g' doc/conf.py || die
+
+		esetup.py build_doc --build-dir "${S}"/build/doc/
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd tests/ || die
+	${EPYTHON} 00_run_all_tests.py --verbose || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc ; then
+		local HTML_DOCS=( build/doc/html/. )
+	fi
+
+	distutils-r1_python_install_all
+}