dev-python/hypothesis: Bump to 6.17.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2021-08-31 09:56:39 +02:00
parent 95e2387433
commit 199b94c112
2 changed files with 63 additions and 0 deletions
+1
View File
@@ -7,3 +7,4 @@ DIST hypothesis-python-6.16.0.tar.gz 9140064 BLAKE2B 74d2963f71b357c1fcf5410271e
DIST hypothesis-python-6.17.0.tar.gz 9142908 BLAKE2B e366f5355e13471c211e91a54fc70e46e3c575d06352968ce4ec3f5cbae0c5442d07c5fefb0907664f262f3ddd1fc50f202d4e93deedea380221e9cba796f0b5 SHA512 320dddaa88a697e6b2fdd942fc08bce0cb1c49f4eeb0de39a7d404d98971d60b0edb332d9d2dd5f3a63b37301d458e361ebd995ccca6554e784e772a7cb3ed6f
DIST hypothesis-python-6.17.1.tar.gz 9143619 BLAKE2B c878313e062c37c8040efe7e659d39699690e066accd67fac1ae92abaff413eadf1a37e1c07ad7effc609ed5d0766274ef74272733088b5897fbad7eb25151a1 SHA512 6418f850b6642337d11bee7d78f82d061af1dd3a2e59dcda1e87ef88f99bda23ccbd6e6cb6cce00275380ddf125c77102bf88ae6a3884d754ef9f7cf9b68e4f5
DIST hypothesis-python-6.17.3.tar.gz 9143941 BLAKE2B a23fd20fb46cb76f6ce57dccbfef182ddd57155e7cec0042ca593ce6176b9699901a5d7fc5092b321270420ac8ec729a7992b55674769216e9b81c53e3144db0 SHA512 c35dce24d3cb6de78e6f2699a67de3db165ecf5a26fa817f45c7b3af057b73a60a47299bbb66bacddb47eefdc0fc36457acab643bf7b256b79fa9387cab79427
DIST hypothesis-python-6.17.4.tar.gz 9144209 BLAKE2B b110e355b34f386c51e9edeb2589bf11e5d0b574ee7e97437f9eba9ec7d8e823e68ad1e4f5911a1e78f3d5a316f59056301b0238c4b6a8cdcb21e46ea434686c SHA512 95eeadc1655d249008897035660af54f66e8ea78fea78d1069dbddb979505e003d1bdb971371769e90af4a7bc5f96ee0c42a6c14bc42e56677d4f89f39985d41
@@ -0,0 +1,62 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 multiprocessing optfeature
DESCRIPTION="A library for property based testing"
HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
IUSE="cli"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' python3_{7..9})
)
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/typing-3.7.4.1
)
"
distutils_enable_tests --install pytest
python_prepare() {
if ! use cli || ! has "${EPYTHON}" python3.{7..9}; then
sed -i -e '/console_scripts/d' setup.py || die
fi
}
python_test() {
distutils_install_for_testing
epytest tests/cover tests/pytest tests/quality \
-p no:pytest-describe \
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}