diff --git a/dev-python/tifffile/Manifest b/dev-python/tifffile/Manifest
index 5dd89393c60d7..56f7b52ba671c 100644
--- a/dev-python/tifffile/Manifest
+++ b/dev-python/tifffile/Manifest
@@ -1 +1,2 @@
+DIST tifffile-2025.10.16.gh.tar.gz 362127 BLAKE2B df4b16596110f7db0ea6c2f371a14e4dc92f45a3337535c7f276c20c3daf7845eb90f5874f8a9281b226cafc085ef2725d6004e80b9aacb015a7aabee50ef402 SHA512 066817c268f4a3207261857b24ba2d2b7f100aedd1947d8b0d8b0a54a0dee6cb71ca0213555ab598457d2d98bda09f4cd57ec8c76b03024e2727a8b7e9b95588
 DIST tifffile-2025.10.4.gh.tar.gz 359732 BLAKE2B 5dd69e8a8fbaf39f18c7ed1edc25aaf1e2c12fdaf6593c84b4346dd58471e9ed13c7ca491ead1321c87e98128c19d68c8504aefb5440a2d52766ced942512f6c SHA512 20c3786d8d85eac2a52f38f4e578ef24dfa8eaa2a60bf200a061742af0dc8fcc278939f542ea9a225add02b563932d17f07d160e3a1d5e34ba26502b58b3d52e
diff --git a/dev-python/tifffile/tifffile-2025.10.16.ebuild b/dev-python/tifffile/tifffile-2025.10.16.ebuild
new file mode 100644
index 0000000000000..fa979d88561cd
--- /dev/null
+++ b/dev-python/tifffile/tifffile-2025.10.16.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Read and write TIFF files"
+HOMEPAGE="
+	https://pypi.org/project/tifffile/
+	https://github.com/cgohlke/tifffile/
+	https://www.cgohlke.com/
+"
+SRC_URI="
+	https://github.com/cgohlke/tifffile/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/numpy-1.19.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/defusedxml[${PYTHON_USEDEP}]
+		>=dev-python/fsspec-2021.5.0[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# not marked properly
+		# https://github.com/cgohlke/tifffile/pull/308
+		tests/test_tifffile.py::test_issue_dcp
+		# meaningless and broken on py<3.13
+		# https://github.com/cgohlke/tifffile/pull/309
+		tests/test_tifffile.py::test_gil_enabled
+	)
+
+	local -x SKIP_LARGE=1
+	local -x SKIP_HTTP=1
+
+	epytest
+}