gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-06 02:17:34 -08:00
Code Issues Projects Releases Wiki Activity

x11-themes/fvwm-crystal: add 3.7.6

Browse Source 
With the dropped dependency on x11-wm/fvwm (masked); destabilise
to match keywords on (and drop keywords to match golang
availability for) x11-wm/fvvm3.

Bug: https://bugs.gentoo.org/949035
Signed-off-by: Matt Jolly <kangie@gentoo.org>
This commit is contained in:
Matt Jolly 2025-04-29 09:33:03 +10:00
parent 7f7e7f9c49
commit 17a876f6a1
No known key found for this signature in database
GPG Key ID: 1B55CE38F469B300
2 changed files with 73 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
x11-themes/fvwm-crystal/Manifest
View File

@ -1 +1,2 @@
DIST fvwm-crystal-3.7.5.tar.gz 5962351 BLAKE2B b5a7458c5bc97846ba48e18168da05d0cda4f26b2f0252abcfd12953de4ac80b34a521759152d559fef59ab53e5f252434d1f1840a779271fc9fffd7ec8632b0 SHA512 333eeeabf1b7b88e1ce7ba5e018a013471db215214b5d9bd86d0f0e107d7443f89bc409e23f3ef4a61c9ced63b862614507cb5ae74063f14d9e0d8b1eb97186b
DIST fvwm-crystal-3.7.6.tar.gz 6015361 BLAKE2B e12327df402c02430ef80def4260d0132143fe6e88924a8b129c2703ff6bd288544592b7b5060bc9840b5d6193b35290f442f39ba247dd47978cd8e607332a97 SHA512 9b680cd59119fea05b23463fb3bbff383370ce66710b99434387ec84de5cde626ea682611a6fd57b55ecdbfdc218ddef89f69924f263a6a953aaabba8cc6c6fe

72
x11-themes/fvwm-crystal/fvwm-crystal-3.7.6.ebuild Normal file
View File

@ -0,0 +1,72 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..13} )
inherit readme.gentoo-r1 python-single-r1 optfeature
DESCRIPTION="Configurable FVWM theme with transparency and freedesktop compatible menu"
HOMEPAGE="https://fvwm-crystal.sourceforge.net/"
if [[ ${PV} = *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/fvwm-crystal/fvwm-crystal.git"
else
SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~ppc64 ~riscv ~x86"
fi
LICENSE="GPL-3+"
SLOT="0"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="${PYTHON_DEPS}
acct-group/fvwm-crystal
app-alternatives/awk
app-alternatives/bc
media-sound/alsa-utils
sys-apps/sed
virtual/imagemagick-tools
x11-apps/xwd
>=x11-wm/fvwm3-1.0.4[go]
|| ( x11-misc/hsetroot media-gfx/feh )
|| ( >=x11-misc/stalonetray-0.6.2-r2 x11-misc/trayer )
"
DISABLE_AUTOFORMATTING="true"
DOC_CONTENTS="After a first time installation, execute the following commands:
$ cp -r "${EROOT}"/usr/share/doc/"${PF}"/addons/Xresources ~/.Xresources
$ cp -r "${EROOT}"/usr/share/doc/"${PF}"/addons/Xsession ~/.xinitrc
You can edit these files at your convenience.
Many applications can extend functionality of fvwm-crystal.
They are listed in "${EROOT}"/usr/share/doc/"${PF}"/INSTALL.*
To be able to use the exit menu, each user using ${PN}
must be in the group fvwm-crystal.
You can do that as root with:
$ useradd -G fvwm-crystal <user_name>
and log out and in again.
"
src_install() {
emake DESTDIR="${ED}" \
docdir="${EPREFIX}/usr/share/doc/${PF}" \
prefix="${EPREFIX}/usr" \
install
# GNU License is globally in the portage tree
rm -vf "${ED}/usr/share/doc/${PF}"/LICENSE || die
python_doscript "${ED}/usr/bin/${PN}".{apps,wallpaper}
python_scriptinto "/usr/share/${PN}"/fvwm/scripts/FvwmMPD
python_doscript "${ED}/usr/share/${PN}"/fvwm/scripts/FvwmMPD/*.py
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
optfeature "localized XDG user directories support" "x11-misc/xdg-user-dirs"
optfeature "hibernate/resume support" "sys-apps/systemd"
optfeature "professional sound server" "virtual/jack"
}