From 16b3d570aaae77e1bd1c792763d88d3cb8b3f1ba Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 23 Nov 2025 05:06:31 +0100
Subject: [PATCH] dev-python/rq: Bump to 2.6.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/rq/Manifest        |  1 +
 dev-python/rq/rq-2.6.1.ebuild | 79 +++++++++++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)
 create mode 100644 dev-python/rq/rq-2.6.1.ebuild

diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index 8c9c2f9af5f2..0d1cc9c4bf8e 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
 DIST rq-2.6.0.tar.gz 675315 BLAKE2B 96ec326d01a1e708dbe7318efc98f1ae5396aca2af0d26836bdcb85483a6c510f9c1ce67c57f9a4211bb5c56a63c083dd0e26cf9f81ab7baa192c79cc09c7a5d SHA512 1e93c84d0fc11841e02fe6fb191c1d490ba80a12a98f8780a025e0c90bd23dda1f9cedfc47fe87f075f8051e7a5368ec5a8376bb53f8163fdec6f755885484bc
+DIST rq-2.6.1.tar.gz 675386 BLAKE2B e66a33618251e5fc8cd8a994c59ec1c0df194bbdb60a31dd5613b57097ffbbd4459069f82b56b26d335bd0e1ae8225a69e49c191c74ce37a04f6c77790a8114c SHA512 209fd3bf08999b41e057c23c15b2b5a7660e6d687ae7225a7ee8c7dd144fc69b67fe7c4be155ff6f8bba3c6ab95f38288055d7889630ca5bcace0e2c45da5fb3
diff --git a/dev-python/rq/rq-2.6.1.ebuild b/dev-python/rq/rq-2.6.1.ebuild
new file mode 100644
index 000000000000..f9f7a193553b
--- /dev/null
+++ b/dev-python/rq/rq-2.6.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
+HOMEPAGE="
+	https://python-rq.org/
+	https://github.com/rq/rq/
+	https://pypi.org/project/rq/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	dev-python/croniter[${PYTHON_USEDEP}]
+	>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+
+EPYTEST_DESELECT=(
+	# requires <sentry-sdk-2
+	tests/test_sentry.py::TestSentry::test_failure_capture
+	# hang
+	tests/test_commands.py::TestCommands::test_shutdown_command
+	tests/test_worker_pool.py::TestWorkerPool::test_check_workers
+	tests/test_worker_pool.py::TestWorkerPool::test_reap_workers
+	tests/test_dependencies.py::TestDependencies
+	# already present in older versions
+	tests/test_spawn_worker.py::TestWorker::test_work_and_quit
+)
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# strip pin
+	sed -i -e '/dependencies/s:,!=[0-9.]*::' pyproject.toml || die
+}
+
+src_test() {
+	local -x TZ=UTC
+
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the actual tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}