diff --git a/games-emulation/ppsspp/Manifest b/games-emulation/ppsspp/Manifest
index e92e132dac2bd..eef7444474789 100644
--- a/games-emulation/ppsspp/Manifest
+++ b/games-emulation/ppsspp/Manifest
@@ -1 +1,2 @@
 DIST ppsspp-1.17.1.tar.xz 54663108 BLAKE2B 91c4964c9f334d42e090f59485e2f02ba8edb780903d2fa46e1a9cea77f6cc9e1a0605310d76445738259c0e99d5d1ca0764ef5f5565e781b482d5d5274620e5 SHA512 eaa0046f5d8e529efd8238690fa242638aa88630172abe59c4b7ffb16b1e18eeb38fcaf8e70ef76dbd2304b226d1f33e10cde709abe00fa2a5baff16c1883c31
+DIST ppsspp-1.18.1.tar.xz 54239412 BLAKE2B c0a59b63be4fdf8db1bb4c30192adc37874f1976baa0876a21722d8b86dac5a245cd5dbcea2f9ca89fef2035338c1786bbcf9b3c379d48d5a633ddd263b6e8d3 SHA512 00531109d67a35fe252b1af7d41a41ec85950f5d7c818bcdfb713d74b2b94f81f5af12e3e68d49ab0f7c7d29ccc42ca3ae7956f438964a205004293bb7e07510
diff --git a/games-emulation/ppsspp/ppsspp-1.18.1.ebuild b/games-emulation/ppsspp/ppsspp-1.18.1.ebuild
new file mode 100644
index 0000000000000..0313b1d5fe21c
--- /dev/null
+++ b/games-emulation/ppsspp/ppsspp-1.18.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit flag-o-matic python-any-r1 xdg cmake
+
+DESCRIPTION="A PSP emulator written in C++"
+HOMEPAGE="https://www.ppsspp.org/
+	https://github.com/hrydgard/ppsspp/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/hrydgard/${PN}.git"
+else
+	SRC_URI="https://github.com/hrydgard/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="Apache-2.0 BSD BSD-2 GPL-2 JSON MIT"
+SLOT="0"
+IUSE="discord qt5 test wayland"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/snappy:=
+	app-arch/zstd:=
+	dev-libs/libzip:=
+	media-libs/glew:=
+	media-libs/libpng:=
+	media-libs/libsdl2[joystick]
+	media-video/ffmpeg:0/58.60.60
+	sys-libs/zlib:=
+	virtual/opengl
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[-gles2-only]
+		dev-qt/qtmultimedia:5[-gles2-only]
+		dev-qt/qtopengl:5[-gles2-only]
+		dev-qt/qtwidgets:5[-gles2-only]
+	)
+	!qt5? (
+		media-libs/libsdl2[X,opengl,sound,video,wayland?]
+	)
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.17.1-SpvBuilder-cstdint.patch"
+	"${FILESDIR}/${PN}-1.17.1-cmake-cxx.patch"
+	"${FILESDIR}/${PN}-CMakeLists-flags.patch"
+)
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# bug https://bugs.gentoo.org/926079
+	filter-lto
+
+	local -a mycmakeargs=(
+		-DBUILD_SHARED_LIBS="OFF"
+		-DCMAKE_SKIP_RPATH="ON"
+		-DHEADLESS="OFF"
+		-DUSE_CCACHE="OFF"
+		-DUSE_SYSTEM_FFMPEG="ON"
+		-DUSE_SYSTEM_LIBZIP="ON"
+		-DUSE_SYSTEM_SNAPPY="ON"
+		-DUSE_SYSTEM_ZSTD="ON"
+		-DUSE_DISCORD="$(usex discord)"
+		-DUSE_WAYLAND_WSI="$(usex wayland)"
+		-DUSING_QT_UI="$(usex qt5)"
+		-DUNITTEST="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_src_test -E glslang-testsuite
+}