From 152b7f9ed09be14080153babece7b8476b2f640b Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 12 Sep 2025 06:03:45 +0200
Subject: [PATCH] dev-python/tempest: Bump to 45.0.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/tempest/Manifest              |  1 +
 dev-python/tempest/tempest-45.0.0.ebuild | 75 ++++++++++++++++++++++++
 2 files changed, 76 insertions(+)
 create mode 100644 dev-python/tempest/tempest-45.0.0.ebuild

diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index 360ace79d7156..b0e51c4b2aa77 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-44.0.0.tar.gz 1165834 BLAKE2B 909f7ab4ffe2925b3a62bce15a947711cc0ced9a08a81bf477285c08a2a8ebf8c7d8284c5d7bb14184858e9e52a513c4f4db5bb1dd196874711a59d327c56fcd SHA512 859b3ea3eee5717337bd054807c5a7841f5512aab7c312e0ff0123645b18f2411865943651414ded619022059e929607bdc6c05cf352fc233a2974d0c50e6b79
+DIST tempest-45.0.0.tar.gz 1171661 BLAKE2B 4978470e3481df1086837685f30b2fa0807e6ae49d0479ebcda4fc514d2034fb2b0f0aac4bbf7246f8ecf3e156dc8cf9d1f4a16b5d298a90f6a82d5ee3af4da1 SHA512 65de92882bda88b2bd52ade54c046e638f43b3e6b213615f1486eb0bd1e04b9360d09653fa480bdb354397b239f7a35658c97f8ff058d3a9617fdfa14f84b280
diff --git a/dev-python/tempest/tempest-45.0.0.ebuild b/dev-python/tempest/tempest-45.0.0.ebuild
new file mode 100644
index 0000000000000..a1a42f0306b97
--- /dev/null
+++ b/dev-python/tempest/tempest-45.0.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/python-subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.16.0[${PYTHON_USEDEP}]
+	>=dev-python/testscenarios-0.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	stestr --test-path ./tempest/tests run --concurrency="$(makeopts_jobs)" ||
+		die "Tests failed for ${EPYTHON}"
+}