From 14f70e97c5ee02419ccf167dcb4b47f2855d82cd Mon Sep 17 00:00:00 2001
From: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Date: Fri, 5 Jun 2026 10:31:03 +0200
Subject: [PATCH] media-sound/audacious: add 4.6

update min versions

It's not worth adding a new rebased patch for GDK_WINOWING, since
there's no backend specific code. It only sets GDK_BACKEND=x11 to
restart properly with the Winamp skin, which depends on
audacious-plugins[X] anyway.

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/1077
Signed-off-by: Sam James <sam@gentoo.org>
---
 media-sound/audacious/Manifest             |  1 +
 media-sound/audacious/audacious-4.6.ebuild | 79 ++++++++++++++++++++++
 2 files changed, 80 insertions(+)
 create mode 100644 media-sound/audacious/audacious-4.6.ebuild

diff --git a/media-sound/audacious/Manifest b/media-sound/audacious/Manifest
index 7546818197603..4d65232fb8f39 100644
--- a/media-sound/audacious/Manifest
+++ b/media-sound/audacious/Manifest
@@ -1 +1,2 @@
 DIST audacious-4.5.1.tar.bz2 642359 BLAKE2B f1862541e95ec4fac16515c9a65a93252cd9f465fc2727a4b296439b0cca77b98f2e3ef994ed5f23c49de2a8a502ddfd5a630566cd2415ccfc5988a48f6ca740 SHA512 e30408164df84a1d3fa3ee116f3690c5c03c6894fa474f01c17af79bf2e4ba72a1b89ca8056581a878d92ecc33e2e1f008d1c927372fb074245b1dcc4d403156
+DIST audacious-4.6.tar.bz2 520091 BLAKE2B 96c42a1b702ae9ae368a99df57b772c9022128ffa947bb13485c39dde251835aa14f0177f401b8909d9258836075f709b50dd0535bc1442822821793c7797b63 SHA512 ac1e7d1f0f3f9b1ae55dc70eecc0d9b7510011e113b6e5ee9d4f8d3eb86127f8624bf11288a567081ce90c7edf35d4fbd73615690eb464513093e15cff7e076d
diff --git a/media-sound/audacious/audacious-4.6.ebuild b/media-sound/audacious/audacious-4.6.ebuild
new file mode 100644
index 0000000000000..72d69afb1835c
--- /dev/null
+++ b/media-sound/audacious/audacious-4.6.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+SRC_URI="https://distfiles.audacious-media-player.org/${P}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="gtk qt6 test"
+REQUIRED_USE="test? ( qt6 )"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	>=dev-util/gdbus-codegen-2.80.5-r1
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/glib-2.36:2
+	virtual/freedesktop-icon-theme
+	gtk? (
+		x11-libs/cairo
+		x11-libs/gdk-pixbuf:2
+		>=x11-libs/gtk+-3.24:3
+		x11-libs/pango
+	)
+	qt6? (
+		dev-qt/qtbase:6[gui,widgets]
+		dev-qt/qtsvg:6
+	)
+"
+RDEPEND="${DEPEND}"
+PDEPEND="~media-plugins/audacious-plugins-${PV}[gtk=,qt6=]"
+
+src_configure() {
+	# D-Bus is a mandatory dependency. Remote control,
+	# session management and some plugins depend on this.
+	# Building without D-Bus is *unsupported* and a USE-flag
+	# will not be added due to the bug reports that will result.
+	# Bugs #197894, #199069, #207330, #208606
+	local emesonargs=(
+		-Ddbus=true
+		$(meson_use qt6 qt)
+		-Dqt5=false
+		$(meson_use gtk)
+		-Dgtk2=false
+		-Dlibarchive=false
+		-Dbuildstamp="Gentoo ${P}"
+		-Dvalgrind=false
+	)
+	meson_src_configure
+
+	if use test; then
+		emesonargs=()
+		EMESON_SOURCE="${S}"/src/libaudcore/tests \
+		BUILD_DIR="${WORKDIR}"/${P}-libaudcore_tests-build \
+		meson_src_configure
+	fi
+}
+
+src_compile() {
+	meson_src_compile
+
+	if use test; then
+		EMESON_SOURCE="${S}"/src/libaudcore/tests \
+		BUILD_DIR="${WORKDIR}"/${P}-libaudcore_tests-build \
+		meson_src_compile
+	fi
+}
+
+src_test() {
+	BUILD_DIR="${WORKDIR}"/${P}-libaudcore_tests-build meson_src_test
+}