diff --git a/net-dns/hash-slinger/Manifest b/net-dns/hash-slinger/Manifest
index 547aca0f12cdb..a32bab4a44c14 100644
--- a/net-dns/hash-slinger/Manifest
+++ b/net-dns/hash-slinger/Manifest
@@ -1 +1,2 @@
 DIST hash-slinger-3.3.tar.gz 38597 BLAKE2B 237affa3f933d3dbd1dca3bc4f927268c15d10eed16c18aae68906f1fe6511eda48283f76da851d70535139bc880074951a1ab4c6be92bd27e32c38e374ce044 SHA512 ba59771d32a93f500b61beab1d44e6edf94965c1a7cb30708e4722fe7e6d97a884ccd0e16c9058c29b174a710c13d562b1b6dfc15edc7440692494744392a52e
+DIST hash-slinger-3.4.tar.gz 38668 BLAKE2B c2aaaa0a0329a85105891fa50a780b400ad9a855a66de758eac32ee658d253d103e4dfcab969019499af31d59cc6cac0b6c538d130ab8326d1c5bf30e92ddf32 SHA512 0f49a10bc4ecfe6ef2e209590f2c32ff11193bd421957d855881cb9f03d7f39912c39f72e32018a5e338ac55368b81693bc07881bdb8dbe8e57f99d3b487fd0f
diff --git a/net-dns/hash-slinger/hash-slinger-3.4.ebuild b/net-dns/hash-slinger/hash-slinger-3.4.ebuild
new file mode 100644
index 0000000000000..7b45431b34729
--- /dev/null
+++ b/net-dns/hash-slinger/hash-slinger-3.4.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit python-single-r1
+
+DESCRIPTION="Various tools to generate DNS records like SSHFP, TLSA, OPENPGPKEY, IPSECKEY"
+HOMEPAGE="https://github.com/letoams/hash-slinger"
+SRC_URI="https://github.com/letoams/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="ipsec +openpgp +ssh"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/dnspython[${PYTHON_USEDEP}]
+		dev-python/m2crypto[${PYTHON_USEDEP}]
+	')
+	net-dns/unbound[python,${PYTHON_SINGLE_USEDEP}]
+	ipsec? ( net-vpn/libreswan[dnssec] )
+	openpgp? ( $(python_gen_cond_dep 'dev-python/python-gnupg[${PYTHON_USEDEP}]') )
+	ssh? ( virtual/openssh )
+"
+
+src_install() {
+	local tools tool
+
+	tools="tlsa"
+
+	use ssh	&& tools+=" sshfp"
+	use openpgp && tools+=" openpgpkey"
+	use ipsec && tools+=" ipseckey"
+
+	for tool in $tools ; do
+		doman ${tool}.1
+		python_doscript ${tool}
+	done
+
+	dodoc BUGS CHANGES README
+}