diff --git a/dev-python/nox/Manifest b/dev-python/nox/Manifest
index 41a5d3822958..a0662c61ba47 100644
--- a/dev-python/nox/Manifest
+++ b/dev-python/nox/Manifest
@@ -1 +1,2 @@
 DIST nox-2025.10.16.gh.tar.gz 4030415 BLAKE2B 1ad98e773c387669f10de8879bb81d9aeb549f30ba8976e5f8d97589df967244a81138f0dc2e7ff2ddc40e81d694ed8bbf89aa11d9988c615f0b4af100e0b495 SHA512 992bb658ffbc889eeb584a4c3c8785f2a251f111fc0cd4fbe35eb67b5463a45772cefebf2ef2e88d337e4ff7879da47ad0ec07082e904968e7e1996a7d79127d
+DIST nox-2025.11.12.gh.tar.gz 4030743 BLAKE2B f5d611c37179bb850757d24077a8f4c00a4cd76c26c79ce93eb549c27fd116fdbd1d5380f027dc1355c40ed710b7b1190a15df8294e9a448bdd685ca1c26306c SHA512 fe660f99263ef950e79ae70bd4beeee88046bf2f838e36e33ac74fba5bdd3d36f898a2d7194716f832222a13061f52ad6c03da7f4e3fc5c296ca6db04a48e13f
diff --git a/dev-python/nox/nox-2025.11.12.ebuild b/dev-python/nox/nox-2025.11.12.ebuild
new file mode 100644
index 000000000000..3617fc027080
--- /dev/null
+++ b/dev-python/nox/nox-2025.11.12.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Flexible test automation for Python"
+HOMEPAGE="
+	https://github.com/wntrblm/nox/
+	https://pypi.org/project/nox/
+"
+SRC_URI="
+	https://github.com/wntrblm/nox/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	>=dev-python/attrs-24.1[${PYTHON_USEDEP}]
+	>=dev-python/colorlog-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/dependency-groups-1.1[${PYTHON_USEDEP}]
+	>=dev-python/humanize-4[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.15[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pbs-installer-2025.01.06[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: conda?
+		'tests/test_sessions.py::TestSessionRunner::test__create_venv_options[nox.virtualenv.CondaEnv.create-conda-CondaEnv]'
+		# Internet
+		tests/test_virtualenv.py::test_uv_install
+		tests/test_main.py::test_noxfile_script_mode
+	)
+
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# hardcoded CPython assumption
+				tests/test_tox_to_nox.py::test_commands_with_requirements
+				tests/test_tox_to_nox.py::test_skipinstall
+				tests/test_tox_to_nox.py::test_trivial
+				tests/test_tox_to_nox.py::test_usedevelop
+			)
+			;;
+	esac
+
+	epytest -o tmp_path_retention_policy=all
+}