From 11cf65710171dc3c1099bbab21ff788b8afe554b Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 24 Mar 2026 04:09:16 +0100
Subject: [PATCH] dev-python/metakernel: Bump to 1.0.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/metakernel/Manifest                |  1 +
 dev-python/metakernel/metakernel-1.0.0.ebuild | 63 +++++++++++++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 dev-python/metakernel/metakernel-1.0.0.ebuild

diff --git a/dev-python/metakernel/Manifest b/dev-python/metakernel/Manifest
index 578fe48353149..eaa1ed37c7371 100644
--- a/dev-python/metakernel/Manifest
+++ b/dev-python/metakernel/Manifest
@@ -1 +1,2 @@
 DIST metakernel-0.32.0.tar.gz 460794 BLAKE2B eaa4641e836e9806eae214b14d71cec494aa4a87caeb497f5d197e04e88f010acbec5f3220d5cd15a1e40818018f0f3bad9223c80f0efd2de10e90b4bd1018bd SHA512 8393c687d558e058d1b10378da65e9e1bf8528b3996b238de1756e5c3bd9e3282cdb0dadebc62c49e3e55bc1a0227e36db7a58cd4a8bdc7469f943854089b978
+DIST metakernel-1.0.0.tar.gz 229742 BLAKE2B 4508337e3679e9b502402569472187d23c61e3622dc79748b13e32d865af28efde2e219264646150eb404fd093a659a656cdb76e4b0881ee0b81574d7fc81513 SHA512 d76b25c1842958503156aee83ae01c15de7dc80acc7ed6fce616bfb93143275ad90284c43b9fb521c4a1a61cef7b8ec69a990ccbbd241cdfd0d4d3c479da8a4b
diff --git a/dev-python/metakernel/metakernel-1.0.0.ebuild b/dev-python/metakernel/metakernel-1.0.0.ebuild
new file mode 100644
index 0000000000000..a97090325967e
--- /dev/null
+++ b/dev-python/metakernel/metakernel-1.0.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Metakernel for Jupyter"
+HOMEPAGE="
+	https://github.com/Calysto/metakernel/
+	https://pypi.org/project/metakernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.3[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.22.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.19.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.9.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/ipython-9.0[${PYTHON_USEDEP}]
+		>=dev-python/ipywidgets-8.0.5[${PYTHON_USEDEP}]
+		>=dev-python/jupyter-kernel-test-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.29.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-timeout )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile
+		tests/test_parser.py::test_path_completions
+		# broken by color codes in output
+		# https://github.com/Calysto/metakernel/issues/266
+		tests/test_replwrap.py::REPLWrapTestCase::test_bash
+		# requires starting ipycluster
+		tests/magics/test_parallel_magic.py::test_parallel_magic
+	)
+
+	case ${EPYTHON} in
+		python3.1[34])
+			EPYTEST_DESELECT+=(
+				# "not stdin handler available"
+				tests/test_replwrap.py::REPLWrapTestCase::test_spawn_args
+				tests/test_replwrap.py::REPLWrapTestCase::test_spawn_no_args
+			)
+			;;
+	esac
+
+	epytest
+}