dev-python/astrodendro: initial import

Package-Manager: Portage-2.3.3, Repoman-2.3.1

dev-python/astrodendro/Manifest

@@ -0,0 +1 @@
+DIST astrodendro-0.2.0.tar.gz 4594802 SHA256 fa4fe942d1c6d80224bb8930fb5455275c70cd10211412634139bdd91fa1fce8 SHA512 2079e2844537b74b8c40a5e2d9c04a2e7940f12fa0ac77dc95f39d7ea623ad43d8635043336f5cedff6076599a44c4b8908dbd0b67d33c47310408496bce1b1d WHIRLPOOL 6cc56dcf8af8e7ea889c6c266e80de155eb1e10c38fc11c4e4b328bc78f23895a38bee45488499ed2a08b8cb3662e14a9a8d0b1adc6d5b29a850e0c70a7944bb

dev-python/astrodendro/astrodendro-0.2.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1 xdg-utils virtualx
+
+DESCRIPTION="Python package for computation of astronomical dendrograms"
+HOMEPAGE="http://www.dendrograms.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/h5py[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+	   dev-python/matplotlib[${PYTHON_USEDEP}]
+	   dev-python/mock[${PYTHON_USEDEP}]
+	   dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# use system astropy-helpers instead of bundled one
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	xdg_environment_reset
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

dev-python/astrodendro/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-astronomy@gentoo.org</email>
+    <name>Gentoo Astronomy Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    The astrodendro package provides an easy way to compute
+    dendrograms of observed or simulated Astronomical data in Python.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">astrodendro</remote-id>
+  </upstream>
+</pkgmetadata>