From 0fee17100e42b3229b28a3d16f2b28a09c41a539 Mon Sep 17 00:00:00 2001
From: Ian Jordan <immoloism@gmail.com>
Date: Sun, 27 Jul 2025 00:39:18 +0100
Subject: [PATCH] app-accessibility/espeakup: Add module autoloading

Adding the speakup_soft module to be autoloaded when installing this package as it will fail launch the service without it enabled.

This will greatly improve accessibility under Gentoo including the offerings we support in the live media.

Bumped to EAPI8 as a freebie.

Signed-off-by: Ian Jordan <immoloism@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/43178
Closes: https://github.com/gentoo/gentoo/pull/43178
Signed-off-by: Sam James <sam@gentoo.org>
---
 .../espeakup/espeakup-0.90-r2.ebuild          | 61 +++++++++++++++++++
 .../espeakup/espeakup-9999.ebuild             |  8 ++-
 .../espeakup/files/modules.espeakup           |  1 +
 3 files changed, 67 insertions(+), 3 deletions(-)
 create mode 100644 app-accessibility/espeakup/espeakup-0.90-r2.ebuild
 create mode 100644 app-accessibility/espeakup/files/modules.espeakup

diff --git a/app-accessibility/espeakup/espeakup-0.90-r2.ebuild b/app-accessibility/espeakup/espeakup-0.90-r2.ebuild
new file mode 100644
index 0000000000000..30061f2f14707
--- /dev/null
+++ b/app-accessibility/espeakup/espeakup-0.90-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/linux-speakup/espeakup.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/linux-speakup/espeakup/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~x86"
+fi
+
+inherit linux-info meson
+
+DESCRIPTION="espeakup is a small lightweight connector for espeak and speakup"
+HOMEPAGE="https://linux-speakup.org/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="man systemd"
+
+COMMON_DEPEND="app-accessibility/espeak-ng[sound]
+	media-libs/alsa-lib"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="man? ( app-text/ronn-ng )"
+
+CONFIG_CHECK="~SPEAKUP ~SPEAKUP_SYNTH_SOFT"
+ERROR_SPEAKUP="CONFIG_SPEAKUP is not enabled in this kernel!"
+ERROR_SPEAKUP_SYNTH_SOFT="CONFIG_SPEAKUP_SYNTH_SOFT is not enabled in this kernel!"
+
+src_configure() {
+	local emesonargs
+	emesonargs=(
+		$(meson_feature man)
+		$(meson_feature systemd)
+		)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	einstalldocs
+	newconfd "${FILESDIR}"/espeakup.confd espeakup
+	newinitd "${FILESDIR}"/espeakup.initd espeakup
+	insinto /etc/modprobe.d
+	newins "${FILESDIR}/modules.espeakup" espeakup.conf
+
+}
+
+pkg_postinst() {
+	elog "To get espeakup to start automatically, it is currently recommended"
+	elog "that you add it to the default run level, by giving the following"
+	elog "command as root."
+	elog
+	elog "rc-update add espeakup default"
+	elog
+	elog "You can also set a default voice now for espeakup."
+	elog "See /etc/conf.d/espeakup for how to do this."
+}
diff --git a/app-accessibility/espeakup/espeakup-9999.ebuild b/app-accessibility/espeakup/espeakup-9999.ebuild
index 503c5bd7ea0c2..745f48752b474 100644
--- a/app-accessibility/espeakup/espeakup-9999.ebuild
+++ b/app-accessibility/espeakup/espeakup-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="https://github.com/linux-speakup/espeakup.git"
@@ -14,7 +14,7 @@ fi
 inherit linux-info meson
 
 DESCRIPTION="espeakup is a small lightweight connector for espeak and speakup"
-HOMEPAGE="https://github.com/williamh/espeakup"
+HOMEPAGE="https://linux-speakup.org/"
 
 LICENSE="GPL-3"
 SLOT="0"
@@ -42,6 +42,8 @@ src_install() {
 	einstalldocs
 	newconfd "${FILESDIR}"/espeakup.confd espeakup
 	newinitd "${FILESDIR}"/espeakup.initd espeakup
+	insinto /etc/modprobe.d
+	newins "${FILESDIR}/modules.espeakup" espeakup.conf
 }
 
 pkg_postinst() {
diff --git a/app-accessibility/espeakup/files/modules.espeakup b/app-accessibility/espeakup/files/modules.espeakup
new file mode 100644
index 0000000000000..38d53913d181d
--- /dev/null
+++ b/app-accessibility/espeakup/files/modules.espeakup
@@ -0,0 +1 @@
+speakup_soft