sys-libs/snapd-glib: add 1.70

Signed-off-by: Nowa Ammerlaan <nowa@gentoo.org>

sys-libs/snapd-glib/Manifest

@@ -1,2 +1,3 @@
 DIST snapd-glib-1.65.tar.xz 205948 BLAKE2B e5253cd6f8ac908236a89bf8fa3ec2252d2e4bb0875c6860b63808663d80d59d0a5397a5170ac959492e720e1c8fe77d9674a6469cc58556073cf93888da9a8b SHA512 6bae381c6b5a83312004026228ee76e7b8722a5a561c991ceda35aaf104eaf84451f5a7ba299cad6b1f82e3dbcb16cc4780ac393cadb2ca58478b59a809fc613
 DIST snapd-glib-1.67.tar.gz 294573 BLAKE2B 997a3ea1be213f674c91ad94eb7f8ba2b4675d80c2cc362e584607d81278936dfe3902531e98cb177d0225cdf4d0ad2cb715f1ba24a63a22dd7b64b51cbeab85 SHA512 c21c22157f2601f6cf3cc13127a8a3d0ab03609613bbe585da4397093cd9264ab6109fdebf92c7ef3adc9bcb21e6a6f0dbb4d1a5a71dd04470823c723fb5cdcb
+DIST snapd-glib-1.70.tar.gz 299401 BLAKE2B 46d307ee6b837ac73eb45c6462888cf9b4183de6c47f6b8b32987af3f7106de6d5415cbb6ef323c704c7e19ef8085e9f00748558e9cba003178480062eb9b774 SHA512 a2bd1ab52e45a6a38096727d0badabfdbd017a521230f76cdee540bade60df1be80b88b185576e5c82f0f8572fb367f6678dc6a537cc897b5c845f73c2a5c513

sys-libs/snapd-glib/snapd-glib-1.70.ebuild

@@ -0,0 +1,76 @@
+# Copyright 2019-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson vala
+
+DESCRIPTION="glib library for communicating with snapd"
+HOMEPAGE="https://snapcraft.io/"
+SRC_URI="https://github.com/canonical/snapd-glib/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/1"
+KEYWORDS="~amd64"
+
+IUSE="doc introspection qml qt6 vala"
+REQUIRED_USE="
+	qml? ( qt6 )
+	vala? ( introspection )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	sys-devel/gettext
+	qt6? ( dev-qt/qttools:6[linguist] )
+"
+
+DEPEND="
+	dev-libs/json-glib
+	dev-libs/glib:2
+	dev-util/glib-utils
+	net-libs/libsoup:3.0
+	doc? (
+		dev-build/gtk-doc-am
+		dev-util/gi-docgen
+		dev-util/gtk-doc
+	)
+	introspection? ( dev-libs/gobject-introspection )
+	qml? (
+		qt6? ( dev-qt/qtdeclarative:6 )
+	)
+	qt6? (
+		dev-qt/qtbase:6[network,widgets]
+	)
+	vala? ( $(vala_depend) )
+"
+
+RDEPEND="${DEPEND}
+	app-containers/snapd
+"
+
+pkg_setup() {
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		"$(meson_use doc docs)"
+		"$(meson_use introspection)"
+		"$(meson_use qml qml-bindings)"
+		"$(meson_use qt6)"
+		"$(meson_use vala vala-bindings)"
+		-Dsoup2=false
+		-Dqt5=false
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc; then
+		dodir /usr/share/gtk-doc/html/
+		mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/gtk-doc/html/${PF}" || die
+	fi
+}