dev-python/rst-linker: new package, initial version 1.6

required to build dev-python/irc's doc

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/1376

Signed-off-by: Ian Delaney <idella4@gentoo.org>

dev-python/rst-linker/Manifest

@@ -0,0 +1 @@
+DIST rst.linker-1.6.tar.gz 6439 SHA256 e1eab99dba26c4562f1a034bd0122f84035f0e54750b20ca1e017ed225c66a2e SHA512 f2511f2bef0ef90b9b9bcda11542e768d242cde5d617f17bec1c23cb21819510703033c63b3dda2cacae73a605de2d8930512e040c6703dd881b4dc0d7022baf WHIRLPOOL c097a20d3bd3f3cdc7aeade9a586818a47ad282877d47999de6aaa240595849b127ef84ee25e677bcfc21ce9b4b99e3e7fe7b71d8571ba465d0854b1961350c2

dev-python/rst-linker/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sautier.louis@gmail.com</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">rst.linker</remote-id>
+		<remote-id type="github">jaraco/rst.linker</remote-id>
+		<bugs-to>https://github.com/jaraco/rst.linker/issues</bugs-to>
+	</upstream>
+</pkgmetadata>

dev-python/rst-linker/rst-linker-1.6.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Sphinx plugin to add links and timestamps to the changelog"
+HOMEPAGE="https://github.com/jaraco/rst.linker"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	py.test || die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}