From 0d89c5d7e4a91ef2f1043e4ef20fa5e79cd4e1cb Mon Sep 17 00:00:00 2001
From: Gilles Dartiguelongue <eva@gentoo.org>
Date: Tue, 15 Aug 2017 19:32:40 +0200
Subject: [PATCH] =?UTF-8?q?gnome-base/gnome-control-center:=20version=20bu?=
 =?UTF-8?q?mp=203.24.2=20=E2=86=92=203.24.3?=
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-2.3.7, Repoman-2.3.3
---
 gnome-base/gnome-control-center/Manifest      |   1 +
 .../gnome-control-center-3.24.3.ebuild        | 165 ++++++++++++++++++
 2 files changed, 166 insertions(+)
 create mode 100644 gnome-base/gnome-control-center/gnome-control-center-3.24.3.ebuild

diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index 671574759fb53..d59503cbc52da 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-control-center-3.22.2.tar.xz 7277380 SHA256 7512ff3e256c1d43a746752e90a8079d0b064aae35283cfe863e19706ce22f92 SHA512 a9ed72c47703fcbbd0d6f3301be7d5b3a8eff2f0c400bde19e14c5d013404fc5907765fb20af40022f7700547d06c02203a919b4db4c191f64f3ac20cb12626a WHIRLPOOL 393fa9d1752330ebac81215f35df5da6ed4b457cbc5ce56a5497191584266161c4ab0105b16535ef245be62aec27c6556fca2416ce7b91651b266f224592b686
 DIST gnome-control-center-3.24.2.tar.xz 7269112 SHA256 382a4b1bf54754c1f5f83adb1faeca2e9de70df5d3d85ac6b0fb192801518f2b SHA512 5041d4907cba0ea188663ad574ddaac6c341ec22b69f7a3d6332b8ae0a572fe33eb19eed758f3d593fe6224d793f2ecc3677584ebf0971f3ae145363a1769cc0 WHIRLPOOL 6e42ec6ac877eb19cc64d5d52106662a872cd4cba25bf0fb2f0fa4a4c1d82fc4149a52f7922e1e1e6dd005133cf54d5e154f75807da58d510e7d09610b41cb7b
+DIST gnome-control-center-3.24.3.tar.xz 7302120 SHA256 43a4d2a4c222ee4a53428a4a720f823e157e4d4c597ea1a84e438d242596cca2 SHA512 70b827f70fb95e8db0ee01e3ba80242dfdb0f90e31c391ca470c372cb6c8626f054e1e5b79e954935e9b567564129b80957091039e16e921e1c93b3d584c71cb WHIRLPOOL 3e5b9c47ef2ecf9fdba3037ace51eefab765e7dfa829586b90da267ccbd099658f48967600aaaa3259796e56805fe3c90fa55577787ca84bdd5e6cfb2729757b
diff --git a/gnome-base/gnome-control-center/gnome-control-center-3.24.3.ebuild b/gnome-base/gnome-control-center/gnome-control-center-3.24.3.ebuild
new file mode 100644
index 0000000000000..4935e46c8860a
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-3.24.3.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+GNOME2_EAUTORECONF="yes"
+
+inherit bash-completion-r1 gnome2
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-control-center/"
+
+LICENSE="GPL-2+"
+SLOT="2"
+IUSE="+bluetooth +colord +cups debug +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager v4l wayland"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+# False positives caused by nested configure scripts
+QA_CONFIGURE_OPTIONS=".*"
+
+# gnome-session-2.91.6-r1 is needed so that 10-user-dirs-update is run at login
+# g-s-d[policykit] needed for bug #403527
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# udev could be made optional, only conditions gsd-device-panel
+# (mouse, keyboards, touchscreen, etc)
+# display panel requires colord
+# printer panel requires cups and smbclient (the latter is not patch yet to be separately optional)
+COMMON_DEPEND="
+	>=dev-libs/glib-2.44.0:2[dbus]
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=x11-libs/gtk+-3.22.0:3[X,wayland?]
+	>=gnome-base/gsettings-desktop-schemas-3.21.4
+	>=gnome-base/gnome-desktop-3.21.2:3=
+	>=gnome-base/gnome-settings-daemon-3.23.90[colord?,policykit]
+	>=x11-misc/colord-0.1.34:0=
+
+	>=dev-libs/libpwquality-1.2.2
+	dev-libs/libxml2:2
+	gnome-base/libgtop:2=
+	media-libs/fontconfig
+	>=sys-apps/accountsservice-0.6.39
+
+	>=media-libs/libcanberra-0.13[gtk3]
+	>=media-sound/pulseaudio-2[glib]
+	>=sys-auth/polkit-0.97
+	>=sys-power/upower-0.99:=
+
+	virtual/libgudev
+	x11-apps/xmodmap
+	x11-libs/cairo
+	x11-libs/libX11
+	x11-libs/libXxf86misc
+	>=x11-libs/libXi-1.2
+
+	bluetooth? ( >=net-wireless/gnome-bluetooth-3.18.2:= )
+	colord? (
+		net-libs/libsoup:2.4
+		>=x11-misc/colord-0.1.34:0=
+		>=x11-libs/colord-gtk-0.1.24 )
+	cups? (
+		>=net-print/cups-1.4[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	gnome-online-accounts? (
+		>=media-libs/grilo-0.3.0:0.3=
+		>=net-libs/gnome-online-accounts-3.21.5:= )
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	kerberos? ( app-crypt/mit-krb5 )
+	networkmanager? (
+		>=gnome-extra/nm-applet-1.2.0
+		>=net-misc/networkmanager-1.2.0:=[modemmanager]
+		>=net-misc/modemmanager-0.7.990 )
+	v4l? (
+		media-libs/clutter-gtk:1.0
+		>=media-video/cheese-3.5.91 )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7
+		>=media-libs/clutter-1.11.3:1.0
+		media-libs/clutter-gtk:1.0
+		>=x11-libs/libXi-1.2 )
+"
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+# libgnomekbd needed only for gkbd-keyboard-display tool
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${COMMON_DEPEND}
+	|| ( >=sys-apps/systemd-31 ( app-admin/openrc-settingsd sys-auth/consolekit ) )
+	x11-themes/adwaita-icon-theme
+	colord? ( >=gnome-extra/gnome-color-manager-3 )
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	input_devices_wacom? ( gnome-base/gnome-settings-daemon[input_devices_wacom] )
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 ) )
+
+	!<gnome-base/gdm-2.91.94
+	!<gnome-extra/gnome-color-manager-3.1.2
+	!gnome-extra/gnome-media[pulseaudio]
+	!<gnome-extra/gnome-media-2.32.0-r300
+	!<net-wireless/gnome-bluetooth-3.3.2
+"
+# PDEPEND to avoid circular dependency
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1"
+
+DEPEND="${COMMON_DEPEND}
+	x11-proto/xproto
+	x11-proto/xf86miscproto
+	x11-proto/kbproto
+
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=dev-util/intltool-0.40.1
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+
+	gnome-base/gnome-common
+	sys-devel/autoconf-archive
+"
+# Needed for autoreconf
+#	gnome-base/gnome-common
+#	sys-devel/autoconf-archive
+
+PATCHES=(
+	# Make some panels and dependencies optional; requires eautoreconf
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	"${FILESDIR}"/3.24.2-optional.patch
+	"${FILESDIR}"/3.24.2-optional-wayland.patch
+	"${FILESDIR}"/3.24.2-optional-networkmanager.patch
+	"${FILESDIR}"/3.24.2-optional-cups.patch
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${FILESDIR}"/3.24.2-gentoo-paths.patch
+	# https://bugzilla.gnome.org/show_bug.cgi?id=780544
+	"${FILESDIR}"/3.24.2-fix-without-gdkwayland.patch
+)
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-update-mimedb \
+		--disable-static \
+		--enable-documentation \
+		$(use_enable bluetooth) \
+		$(use_enable colord color) \
+		$(use_enable cups) \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable gnome-online-accounts goa) \
+		$(use_enable ibus) \
+		$(use_enable kerberos) \
+		$(use_enable networkmanager) \
+		$(use_with v4l cheese) \
+		$(use_enable input_devices_wacom wacom) \
+		$(use_enable wayland)
+}
+
+src_install() {
+	gnome2_src_install completiondir="$(get_bashcompdir)"
+}