diff --git a/net-libs/ngtcp2/Manifest b/net-libs/ngtcp2/Manifest
index 26f3ec4737606..a05ec00f13eca 100644
--- a/net-libs/ngtcp2/Manifest
+++ b/net-libs/ngtcp2/Manifest
@@ -11,3 +11,5 @@ DIST ngtcp2-1.23.0.tar.xz 708136 BLAKE2B c5ca36a1fb172598a0c9226b8b157259e18b861
 DIST ngtcp2-1.23.0.tar.xz.asc 833 BLAKE2B 44abc9177667480ba8a7a72378b99fb97ed608a245bc0d9f31564c5739ea80ef0aba39e691269fe6de167956e5c1891349720bc64024a1fadea2c4a33bc4f857 SHA512 e20dd30be8409a9476f6b720c9dae708ec076d6a4324a49d655a99970f24293d8a2aa37aa8490003594016db4a44d0b46ffb835ac42f765a9d1226b6f299a5e8
 DIST ngtcp2-1.24.0.tar.xz 702424 BLAKE2B a459d08fa5d55f4de482fafd5c1809fa47c3e3b7703ac15f5b142944667ccb4a525fcc0a07d8d895d42121b8fbe676e832e02f54112ea2bb29ffee795b30b6c2 SHA512 e8c862c4bef6f1b75eec7808a4c6f5e7aba4d38bf06428fa02878d64685ff234528688639d7dd8907e1efa12da04198dd91d05e17a2925f9a785d04bd469d52f
 DIST ngtcp2-1.24.0.tar.xz.asc 833 BLAKE2B 35dffc8f9557d6b3a6d1a8153abc9beb9d45f54f839588d338bc0a73cbdd81c1c358d39072ee392d5da155d8c6d0f1d59feeb03681858af923c52ff79f134315 SHA512 a776462252aa1fbaa0a922b095e918f947af8a7a2a6dd4662fbc3f5713a98ca652c143a07ec751adc6386b75bd0d73f0e28075d80403bea88e6279de8f3ef641
+DIST ngtcp2-1.25.0.tar.xz 709136 BLAKE2B 3888444283f6bce450ee5ab7961695e47b13ed4858615d3f272ac61614c05ca6fc6332dad60cf844c4dcdc33aa333c1febe3105d263585939a14eb7ccefb9758 SHA512 b5ebf0a4248a13b9231ac0b6353adbf6634a19bb57db3cf39947746c399ebc5085f780a540d246b7226bb994a920ad0cc9b755ebd9fe58c18a6838d50b6bc90e
+DIST ngtcp2-1.25.0.tar.xz.asc 833 BLAKE2B e38ba68d3be33965de428231faaf326a5ac2d28ca5950a9046df7a3e2066f00638fc4d675218a1d58dc87e8124daa1cea91838625b9f0e3b36ef91b38c2550f3 SHA512 cf0f325503ccfb65a770980cfd373fa88b9b89c0e56613f0dc058c3edc0a9a1c0324474fb4e58aca68b75831876b1000f7259f77a23db5e51fb07ec3e593e6f7
diff --git a/net-libs/ngtcp2/ngtcp2-1.24.0.ebuild b/net-libs/ngtcp2/ngtcp2-1.24.0.ebuild
index fe4987ac6a13d..5b9272afd1af6 100644
--- a/net-libs/ngtcp2/ngtcp2-1.24.0.ebuild
+++ b/net-libs/ngtcp2/ngtcp2-1.24.0.ebuild
@@ -49,6 +49,7 @@ QA_CONFIG_IMPL_DECL_SKIP=(
 
 src_prepare() {
 	default
+	elibtoolize # bug #978993
 	[[ ${PV} == 9999 ]] && eautoreconf
 }
 
diff --git a/net-libs/ngtcp2/ngtcp2-1.25.0.ebuild b/net-libs/ngtcp2/ngtcp2-1.25.0.ebuild
new file mode 100644
index 0000000000000..ddb0bb95b58e2
--- /dev/null
+++ b/net-libs/ngtcp2/ngtcp2-1.25.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Built with autotools rather than cmake to avoid circular dep (bug #951524
+
+inherit multilib-minimal
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/ngtcp2/ngtcp2.git"
+	inherit autotools git-r3
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/ngtcp2.asc
+	inherit verify-sig
+	SRC_URI="
+		https://github.com/ngtcp2/ngtcp2/releases/download/v${PV}/${P}.tar.xz
+		verify-sig? ( https://github.com/ngtcp2/ngtcp2/releases/download/v${PV}/${P}.tar.xz.asc )
+	"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~arm64-macos ~x64-macos"
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-ngtcp2 )"
+fi
+
+DESCRIPTION="Implementation of the IETF QUIC Protocol"
+HOMEPAGE="https://nghttp2.org/ngtcp2/ https://github.com/ngtcp2/ngtcp2"
+
+LICENSE="MIT"
+SLOT="0/0"
+IUSE="gnutls +openssl +ssl"
+REQUIRED_USE="ssl? ( || ( gnutls openssl ) )"
+
+# Uses SSL_set_quic_tls_cbs to detect OpenSSL. The function was introduced in
+# OpenSSL 3.5:
+# https://docs.openssl.org/master/man3/SSL_set_quic_tls_cbs/#history.
+RDEPEND="
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-3.7.2:=[${MULTILIB_USEDEP}] )
+		openssl? ( >=dev-libs/openssl-3.5:=[${MULTILIB_USEDEP}] )
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND+=" virtual/pkgconfig"
+
+# QuicTLS function, the OpenSSL support is checked via SSL_set_quic_tls_cbs.
+QA_CONFIG_IMPL_DECL_SKIP=(
+	'SSL_provide_quic_data'
+)
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-werror
+		--enable-lib-only
+		$(use_with openssl)
+		$(use_with gnutls)
+		--without-boringssl
+		--without-picotls
+		--without-wolfssl
+		--without-libev
+		--without-libnghttp3
+		--without-jemalloc
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}"/usr -type f -name '*.la' -delete || die
+}
diff --git a/net-libs/ngtcp2/ngtcp2-9999.ebuild b/net-libs/ngtcp2/ngtcp2-9999.ebuild
index 61388a8f13c6a..545305a8d4f6e 100644
--- a/net-libs/ngtcp2/ngtcp2-9999.ebuild
+++ b/net-libs/ngtcp2/ngtcp2-9999.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 # Built with autotools rather than cmake to avoid circular dep (bug #951524
 
-inherit libtool multilib-minimal
+inherit multilib-minimal
 
 if [[ ${PV} == 9999 ]] ; then
 	EGIT_REPO_URI="https://github.com/ngtcp2/ngtcp2.git"