From 0b5dfe563ab4d01868c4c8b6bfe7adac62faac87 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Wed, 30 Apr 2025 20:46:23 +0200
Subject: [PATCH] dev-python/m2crypto: Bump to 0.45.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/m2crypto/Manifest               |  1 +
 dev-python/m2crypto/m2crypto-0.45.1.ebuild | 70 ++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 dev-python/m2crypto/m2crypto-0.45.1.ebuild

diff --git a/dev-python/m2crypto/Manifest b/dev-python/m2crypto/Manifest
index c59b22254a3d0..4ba349f0a8f2d 100644
--- a/dev-python/m2crypto/Manifest
+++ b/dev-python/m2crypto/Manifest
@@ -1 +1,2 @@
 DIST m2crypto-0.44.0.tar.gz 363805 BLAKE2B 0a61574ebee8a82ff2b00fa595870fe8d7e965be893db1e82bd1796703ecec16d7c476185b4b4db754efee1e698f60f20c783d1da04f77ee604afb9a346a2077 SHA512 8f8e9d88852eb003eaad9242ca43a0218354d9af3a6f0d9666ceba0ef2c840cd0aca0ad8493a222eb1de9dd0253c0204dde5530fd6a59ee1c3f29be83ec23458
+DIST m2crypto-0.45.1.tar.gz 363721 BLAKE2B a2e1d78e65825e8ae13196aed8ea902618536a3607670a1b4900fbe5cd893d5badfd0431f6b594a209e49088ffbf6ea3540863a6ee2162ac230742d442322262 SHA512 7915bbb63625f645b6281dbdd2bb60691a6fa0d54ab505a1105d76efad5e0407ce68e38bebd5e0b0773bcbb99025ff7aa7d8df25fe32364d4a33471e6e9466ce
diff --git a/dev-python/m2crypto/m2crypto-0.45.1.ebuild b/dev-python/m2crypto/m2crypto-0.45.1.ebuild
new file mode 100644
index 0000000000000..38b9d4beb95c7
--- /dev/null
+++ b/dev-python/m2crypto/m2crypto-0.45.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2018-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+PYPI_PN="M2Crypto"
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="A Python crypto and SSL toolkit"
+HOMEPAGE="
+	https://gitlab.com/m2crypto/m2crypto/
+	https://pypi.org/project/M2Crypto/
+"
+
+# openssl via src/SWIG/_lib11_compat.i
+LICENSE="BSD-2 openssl"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="abi_mips_n32 abi_mips_n64 abi_mips_o32"
+
+DEPEND="
+	dev-libs/openssl:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-lang/swig-2.0.9
+"
+
+swig_define() {
+	local x
+	for x; do
+		if tc-cpp-is-true "defined(${x})"; then
+			SWIG_FEATURES+=" -D${x}"
+		fi
+	done
+}
+
+src_prepare() {
+	# relies on very exact clock behavior which apparently fails
+	# with inconvenient CONFIG_HZ*
+	sed -e 's:test_server_simple_timeouts:_&:' \
+		-i tests/test_ssl.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	# setup.py looks at platform.machine() to determine swig options.
+	# For exotic ABIs, we need to give swig a hint.
+	local -x SWIG_FEATURES=
+
+	# https://bugs.gentoo.org/617946
+	swig_define __ILP32__
+
+	# https://bugs.gentoo.org/674112
+	swig_define __ARM_PCS_VFP
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest -b -v tests.alltests.suite ||
+		die "Tests failed for ${EPYTHON}"
+}