dev-python/flask-debug: new package, dependency of flask-bootstrap, vn. 0.4.3

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/1353

Signed-off-by: Ian Delaney <idella4@gentoo.org>

dev-python/flask-debug/Manifest

@@ -0,0 +1 @@
+DIST flask-debug-0.4.3.tar.gz 9148 SHA256 059f230304805820955894eb1b3d336067eb3cb7a283cd9b7b3744305d65b827 SHA512 7bc1cf9f88f28e2ca5a24c1454dcdb4e2a450eff3c00329f299c3840032e0803079f565652974f4c3a0e5aac443365ce47a3d2c2fee8e21e2e0c7150367e8816 WHIRLPOOL 1080f045e58865f4dea39696b1acdee8a5a2eb5f5903e49cea5aad919f7c654ba3f78822723aedbec174b8bf952dcf14adcc669956e2e194a2e371d4adab4550

dev-python/flask-debug/flask-debug-0.4.3.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+MY_PN="Flask-Debug"
+DESCRIPTION="Configures Flask applications in a canonical way"
+HOMEPAGE="https://github.com/mbr/Flask-Debug"
+# PyPI tarballs don't include tests
+# https://github.com/mbr/Flask-Debug/pull/2
+SRC_URI="https://github.com/mbr/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/inflection[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+	sed -i "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

dev-python/flask-debug/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sautier.louis@gmail.com</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">Flask-Debug</remote-id>
+		<remote-id type="github">mbr/Flask-Debug</remote-id>
+		<bugs-to>https://github.com/mbr/Flask-Debug/issues</bugs-to>
+	</upstream>
+</pkgmetadata>