diff --git a/dev-libs/libusb-compat/Manifest b/dev-libs/libusb-compat/Manifest
index 638527fb3786c..9b06bb619acdc 100644
--- a/dev-libs/libusb-compat/Manifest
+++ b/dev-libs/libusb-compat/Manifest
@@ -1 +1,2 @@
 DIST libusb-compat-0.1.8.tar.bz2 32845 BLAKE2B f590afd539ad20613647b923d69b9fe8ea60b3f5162766a1d840f35e8f56a949f3defa8b1c40ceb8932cf0bf45b3b5097b9ac04a339242a2b906d4ba320e4245 SHA512 817a16a2c7268e0d73add97c06ec3f6e4fc4b8697bd3129bb6f907f138c2a5dccb662096c4cd0385341053b216afd398b21dfef14676777b906972c9e3af4e3e
+DIST libusb-compat-0.1.9.tar.bz2 328896 BLAKE2B 24ab9efb997fbe24d521b1e1cc68598b97391e7386a1cf9cd80b575536ea75fcc9140fde64cb7896920e1501d234e776860b2fb48ba89b26058cbfda511ba3c6 SHA512 dcc893c2fa16bc7b37496514d20f2775a02a5e4c6937d2e5f01d5aaabe84f909616c68acaeff3e4272a8260b544b3aa7571552879308e814352632a588be08d2
diff --git a/dev-libs/libusb-compat/libusb-compat-0.1.9.ebuild b/dev-libs/libusb-compat/libusb-compat-0.1.9.ebuild
new file mode 100644
index 0000000000000..0043c74a45ee3
--- /dev/null
+++ b/dev-libs/libusb-compat/libusb-compat-0.1.9.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools usr-ldscript multilib-minimal
+
+DESCRIPTION="Userspace access to USB devices (libusb-0.1 compat wrapper)"
+HOMEPAGE="https://libusb.info"
+SRC_URI="https://github.com/libusb/libusb-compat-0.1/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="debug examples"
+
+RDEPEND="
+	>=virtual/libusb-1-r1:1[${MULTILIB_USEDEP}]
+	!dev-libs/libusb:0
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/libusb-config
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myconf=(
+		$(use_enable debug debug-log)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	gen_usr_ldscript -a usb
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use examples; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}