dev-python/pytables: version bump

Package-Manager: Portage-2.3.6, Repoman-2.3.2
This commit is contained in:
Sébastien Fabbro
2017-06-28 04:00:16 +00:00
parent b17c1f7d72
commit 087ddf9a98
2 changed files with 77 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST tables-3.1.1.tar.gz 6715786 SHA256 39b9036376f1185599771c19276f13b5b9119d98f9108f58595745ded3fe2da3 SHA512 b5b2052dd81c4748c5e26c1f61f9f92891f48335b0a553f7602ab11c9029dd673d27b91e24cac0da21a81df0c26dbcd9a438214fa58af1ae831c5f04dfa212a6 WHIRLPOOL 86fd6dc9e12503fdbd23013b75f33a41eadbbac0e6dd5ac9a91476d073195077fc6b3d5ad24b1dd4b4c18ae7ed8abc8ea1708262e52240f4c2c3b1153f8c9e91
DIST tables-3.3.0.tar.gz 7004337 SHA256 8383ccf02e041a5d55494a09fc5514140b4653055a2732c981b5fd0f7408822c SHA512 e19445f0f5f2530d49ce55f258931babb7b05df2366637ddbc306323a1f75b7f7dcf91d70a8cc1f41b182d4cdd9c83872873168592bdcce7bd5acae9f3274f36 WHIRLPOOL f270f741d6886775cc730fbcb79de215fbbe2d9b7b2b6efc6b5b3fa7d141046e7c69daad140ad7cc533b439bfae801ea0e1567939dc4258e5c3b6a88f27cd86c
DIST tables-3.4.2.tar.gz 7593471 SHA256 fdbbea4edb6bad0ac0e53fc7bc6970e78e12eef4944aa4146bcdcb573201676c SHA512 8c3bb9113e5082f8b44866b04728a04dae37fbd576c3259309fc305fd4cc0c4f74925557e74f6bd1bd1fc5150d8091648139c4c702e5ed9f53e0ace11c2ac58b WHIRLPOOL 392e117a3ad372ee91a02ee66994f3c03e67b4ae7473f5761e13215ce33084fc3ac8e9e371ca9b59f374066523bcd3ebbced01c49faaa84d4af75a26811ee35f
+76
View File
@@ -0,0 +1,76 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
PYTHON_REQ_USE="threads(+)"
MY_PN=tables
MY_P=${MY_PN}-${PV}
inherit distutils-r1
DESCRIPTION="Hierarchical datasets for Python"
HOMEPAGE="http://www.pytables.org/"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
LICENSE="BSD"
IUSE="doc examples"
RDEPEND="
app-arch/bzip2:0=
app-arch/lz4:0=
>=app-arch/zstd-1.0.0
>=dev-libs/c-blosc-1.11.1:0=
dev-libs/lzo:2=
>=dev-python/numpy-1.8.1[${PYTHON_USEDEP}]
>=dev-python/numexpr-2.5.2[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
>=sci-libs/hdf5-1.8.15:0=
"
DEPEND="${RDEPEND}
>=dev-python/cython-0.21[${PYTHON_USEDEP}]
"
S="${WORKDIR}/${MY_P}"
DOCS=( ANNOUNCE.txt RELEASE_NOTES.txt THANKS )
python_prepare_all() {
export HDF5_DIR="${EPREFIX}"/usr
rm tables/*.c || die
sed -e "s:/usr:${EPREFIX}/usr:g" \
-i setup.py || die
rm -r c-blosc/{blosc,internal-complibs} || die
distutils-r1_python_prepare_all
}
python_compile() {
python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
distutils-r1_python_compile
}
python_test() {
cd "${BUILD_DIR}"/lib* || die
${EPYTHON} tables/tests/test_all.py || die
}
python_install_all() {
if use doc; then
HTML_DOCS=( doc/html/. )
DOCS+=( doc/scripts )
fi
distutils-r1_python_install_all
if use examples; then
insinto /usr/share/doc/${PF}
doins -r examples
doins -r contrib
docompress -x /usr/share/doc/${PF}/examples
docompress -x /usr/share/doc/${PF}/contrib
fi
}