diff --git a/dev-python/argon2-cffi-bindings/Manifest b/dev-python/argon2-cffi-bindings/Manifest
index d82bd13ecb269..b0fbaf5fa606a 100644
--- a/dev-python/argon2-cffi-bindings/Manifest
+++ b/dev-python/argon2-cffi-bindings/Manifest
@@ -1 +1,2 @@
 DIST argon2-cffi-bindings-21.2.0.tar.gz 1779911 BLAKE2B 3e2e2252e37678661502ca15425196b91a7952d0bb5c7ae4ed35132e9085fbbe5d817c9c1bdec7d94eb583ab6baf9d1e1e454a24415bde1408287c5606745fb9 SHA512 71d023ae96073ed78599e4f4e42f8efcc985cc329adeea00b14b54eaac1e6a545e6ad9b7f4cfdc60a4e9c396f95053c0ccb6f6f67d92f70265f91315fff4a390
+DIST argon2_cffi_bindings-25.1.0.tar.gz 1783441 BLAKE2B 0479127bc3587ddc19a0891b25191f602495cb85136864b8b08179683f9d592a01f727b0ad60b0ca4708d834207a3678748723553f9a9bd15dc46412f40c1139 SHA512 64e387a4997b5a905e177b62d1bfb5fafb3b466c10c759d5305fa3e4ec35b7f386eabd34562157266405114c0c71a8c616e25efd9fd8638de03bcc16cc3df6df
diff --git a/dev-python/argon2-cffi-bindings/argon2-cffi-bindings-25.1.0.ebuild b/dev-python/argon2-cffi-bindings/argon2-cffi-bindings-25.1.0.ebuild
new file mode 100644
index 0000000000000..8fac981ee2f5b
--- /dev/null
+++ b/dev-python/argon2-cffi-bindings/argon2-cffi-bindings-25.1.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Low-level CFFI bindings for the Argon2 password hashing library"
+HOMEPAGE="
+	https://github.com/hynek/argon2-cffi-bindings/
+	https://pypi.org/project/argon2-cffi-bindings/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cpu_flags_x86_sse2"
+
+DEPEND="
+	app-crypt/argon2:=
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-6.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/cffi[${PYTHON_USEDEP}]
+	' 'python*')
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/cffi[${PYTHON_USEDEP}]
+	' 'python*')
+"
+
+DOCS=( CHANGELOG.md README.md )
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_configure() {
+	export ARGON2_CFFI_USE_SYSTEM=1
+	# We cannot call usex in global scope, so we invoke it in src_configure
+	export ARGON2_CFFI_USE_SSE2=$(usex cpu_flags_x86_sse2 1 0)
+	distutils-r1_src_configure
+}