From 07ddcab6fd75b53bd42d485bf35044aea19fb8d8 Mon Sep 17 00:00:00 2001
From: Thomas Beierlein <tomjbe@gentoo.org>
Date: Tue, 10 Mar 2026 17:46:08 +0100
Subject: [PATCH] media-radio/xastir: add 2.2.4

Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>
---
 media-radio/xastir/Manifest            |  1 +
 media-radio/xastir/xastir-2.2.4.ebuild | 76 ++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)
 create mode 100644 media-radio/xastir/xastir-2.2.4.ebuild

diff --git a/media-radio/xastir/Manifest b/media-radio/xastir/Manifest
index e18040dfd70a5..8aa2f9d6119e5 100644
--- a/media-radio/xastir/Manifest
+++ b/media-radio/xastir/Manifest
@@ -1 +1,2 @@
 DIST xastir-2.2.2.tar.gz 2246995 BLAKE2B 254dcfef54b20048219aec43496dd1614d48e31940365ed9b30f9fdc73280827238180a44fdcebf11ccfb405264d228458dcfd20500fc6512425236c270f540a SHA512 f552f2c4132aacf3dcd232fb7d18e4f09192e8071668c2075fc3ba8669485b2f150946e12e7a342da0f77a63d4721e74b573876bae32954d3a0a53c6444edf51
+DIST xastir-2.2.4.tar.gz 4332053 BLAKE2B 9f9774763840a9d16f237b19fde1951f0919234cde4377cfe492de6c05dec4964d88a8c619e378429da1c62f635d71fe2cb2e4041d1dcdc48b0341b912f848ff SHA512 171416b82c87959e33bdd9a63c17b9e2d1260e3c083445e5925721879b32d9fa595e4cdcf7acb51429423ab68bfe94094b068922b7678410b09583eff1b9ed42
diff --git a/media-radio/xastir/xastir-2.2.4.ebuild b/media-radio/xastir/xastir-2.2.4.ebuild
new file mode 100644
index 0000000000000..5a562943009b0
--- /dev/null
+++ b/media-radio/xastir/xastir-2.2.4.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic toolchain-funcs
+
+MY_P=${PN/x/X}-Release-${PV}
+
+DESCRIPTION="X Amateur Station Tracking and Information Reporting"
+HOMEPAGE="https://xastir.org/"
+SRC_URI="https://github.com/Xastir/Xastir/archive/Release-${PV}.tar.gz
+			-> ${P}.tar.gz"
+
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="geotiff"
+
+DEPEND=">=x11-libs/motif-2.3:0
+	x11-libs/libXt
+	x11-libs/libX11
+	x11-libs/libXpm
+	x11-apps/xfontsel
+	dev-libs/libpcre2:=
+	net-misc/curl
+	sys-libs/db:=
+	sci-libs/shapelib:=
+	media-gfx/graphicsmagick:=[-q32]
+	geotiff? ( sci-libs/proj
+		sci-libs/libgeotiff:=
+		media-libs/tiff:= )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	eapply_user
+
+	# fix script location (bug #407185)
+	eapply  "${FILESDIR}"/${PN}-2.1.8-scripts.diff
+
+	eautoreconf
+}
+
+src_configure() {
+	# provide include path to GraphicsMagic for configure stage
+	append-cflags -I/usr/include/GraphicsMagick
+	econf \
+		--with-shapelib \
+		--without-ax25 \
+		--without-festival \
+		--without-gpsman \
+		--without-imagemagick \
+		--with-graphicsmagick \
+		$(use_with geotiff libproj) \
+		$(use_with geotiff)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	rm -rf "${D}"/usr/share/doc/${PN}
+	dodoc AUTHORS ChangeLog CONTRIBUTING.md FAQ README \
+		README.MAPS README.OSM_maps
+}
+
+pkg_postinst() {
+	elog "Kernel mode AX.25 and GPSman library not supported."
+	elog
+	elog "Remember you have to be root to add addditional scripts,"
+	elog "maps and other configuration data under /usr/share/xastir."
+}