app-emacs/org-mode: bump to 9.7.33

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/org-mode/Manifest

@@ -1,2 +1,3 @@
 DIST org-mode-release_9.7.30.tar.gz 2365345 BLAKE2B 7096cce2678cd55ce891914eb99d4c5a24c326f97f7480936191ab982f2c2f8a937ac5dcf4662811674c77b6b1cb754d18d44924625a8a0c600df4c13a9b7f35 SHA512 d38ee13f811c7aca71f03cb35ca9df14d211569375188879a209afc53d868baee6eae30c5032a1390a8753bffda11c6d5694aaa6332db8f5d91d60f55eff1047
 DIST org-mode-release_9.7.31.tar.gz 2365308 BLAKE2B 2edc71ea73a9713909b1f21c35484eb73ee1bca7598071e19a89a900cea6af9c10a61bdab13dee9fe4dbf551311e0e24020b5e0f09541199119f21a06f6d6b2f SHA512 11a42fecb8897b23a43186f6f68444753dcc2b3b28ac41283a8c2561cc8e97022747a6da4f8681cb3f65c81fd93d04f2a0c628d50958093d63cc97eac8c11f40
+DIST org-mode-release_9.7.33.tar.gz 2365647 BLAKE2B faca0f94a0d5dc6fa1dd85d3cbe45e83d8283050c80313e8e06d8b69ef8147f4cddaeb105cdc9f0e4511860ae82d801fd9b7b7cb0b40a204ddb19039b1a8aaca SHA512 7989f09785933a1909d7ee757b32a60bbc1757182fd023b21699a13fb759266ead73f9589bf73f7ce10a7218fb5aa83ab90d37d8fd6a9fcd7ca7622465d80618

app-emacs/org-mode/org-mode-9.7.33.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp readme.gentoo-r1
+
+DESCRIPTION="An Emacs mode for notes and project planning"
+HOMEPAGE="https://orgmode.org/"
+
+if [[ "${PV}" == 9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs/${PN}.git"
+	EGIT_CHECKOUT_DIR="${WORKDIR}/org"
+	S="${WORKDIR}/org"
+else
+	MY_P="${PN}-release_${PV}"
+	SRC_URI="https://git.savannah.gnu.org/cgit/emacs/${PN}.git/snapshot/${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-3+ FDL-1.3+ CC-BY-SA-3.0 odt-schema? ( OASIS-Open )"
+SLOT="0"
+IUSE="doc odt-schema"
+RESTRICT="test"
+
+BDEPEND="
+	doc? ( virtual/texi2dvi )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	# Remove failing tests.
+	rm ./testing/lisp/test-{ob,ob-exp,ob-tangle,ob-shell}.el || die
+}
+
+src_compile() {
+	emake -j1 \
+		ORGVERSION="${PV}" \
+		datadir="${EPREFIX}${SITEETC}/${PN}"
+
+	use doc && emake -j1 pdf card
+}
+
+src_install() {
+	emake -j1 \
+		ORGVERSION="${PV}" \
+		DESTDIR="${D}" \
+		ETCDIRS="styles csl $(use odt-schema && echo schema)" \
+		lispdir="${EPREFIX}${SITELISP}/${PN}" \
+		datadir="${EPREFIX}${SITEETC}/${PN}" \
+		infodir="${EPREFIX}/usr/share/info" \
+		install
+
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	dodoc README.org CONTRIBUTE.org etc/ORG-NEWS
+	use doc && dodoc doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf
+
+	local DOC_CONTENTS="Org mode has a large variety of run-time dependencies,
+		so you may have to install one or more additional packages.
+		A non-exhaustive list of these dependencies may be found at
+		<http://orgmode.org/worg/org-dependencies.html>."
+	readme.gentoo_create_doc
+}