diff --git a/dev-libs/pkcs11-helper/Manifest b/dev-libs/pkcs11-helper/Manifest
index 9db4112de573..06877cf085e4 100644
--- a/dev-libs/pkcs11-helper/Manifest
+++ b/dev-libs/pkcs11-helper/Manifest
@@ -1 +1,2 @@
 DIST pkcs11-helper-1.29.0.tar.bz2 422549 BLAKE2B fec72ac82f1545fc50f80b5b28db12906df32fa3bc65f80541d8bee7f1d1c8062f1f0516344237424022c01d4f390e8a72e3e0262250f3b6c51df92c768d81ee SHA512 c530f5a4b5826a02bfe787a1293a7595d5a0d6348daa16675bd10c6d6734b1f24a3cc73b5b89433cf1edf8815f8b7298fdfd1ed686f096bb5edfb425e9430eb2
+DIST pkcs11-helper-1.30.0.tar.bz2 423196 BLAKE2B bf54d9bd2b416df9ef08316f2da3264cef047201914e084d65d9fd897425e15fc5162177de93ad33c4e6c35f45c10aa5dd26c42aabba6c8bf5ca5e5fa5c18914 SHA512 19fba76e41210cc17f9efa4501d0214d4a5c777ab7b2671888fd280b150bae4a6b190c7f47fb783015f9aa40d409fd6087264e531d6f28d0bed4293dcbf8bdd5
diff --git a/dev-libs/pkcs11-helper/pkcs11-helper-1.30.0.ebuild b/dev-libs/pkcs11-helper/pkcs11-helper-1.30.0.ebuild
new file mode 100644
index 000000000000..295abdf115cb
--- /dev/null
+++ b/dev-libs/pkcs11-helper/pkcs11-helper-1.30.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="PKCS#11 helper library"
+HOMEPAGE="https://github.com/OpenSC/pkcs11-helper"
+SRC_URI="https://github.com/OpenSC/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc gnutls nss test"
+# Fails trying to load /usr/lib/pkcs11/provider.so?
+RESTRICT="!test? ( test ) test"
+
+RDEPEND="
+	>=dev-libs/openssl-0.9.7:=
+	gnutls? ( >=net-libs/gnutls-1.4.4:= )
+	nss? ( dev-libs/nss )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( >=app-text/doxygen-1.4.7 )
+"
+
+src_configure() {
+	local myeconfargs=(
+		--disable-crypto-engine-polarssl
+		--disable-crypto-engine-mbedtls
+		$(use_enable doc)
+		$(use_enable gnutls crypto-engine-gnutls)
+		$(use_enable nss crypto-engine-nss)
+		$(use_enable test tests)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	# bug #555262
+	rm "${ED}"/usr/share/doc/${PF}/COPYING.{BSD,GPL} || die
+
+	find "${ED}" -name '*.la' -delete || die
+}