diff --git a/dev-python/jupyter-server-mathjax/jupyter-server-mathjax-0.2.6-r1.ebuild b/dev-python/jupyter-server-mathjax/jupyter-server-mathjax-0.2.6-r1.ebuild
new file mode 100644
index 000000000000..d4f2476d9c11
--- /dev/null
+++ b/dev-python/jupyter-server-mathjax/jupyter-server-mathjax-0.2.6-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="MathJax resources as a Jupyter Server Extension"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter-server/jupyter_server_mathjax/
+	https://pypi.org/project/jupyter-server-mathjax/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/jupyter-server-1.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/jupyter-packaging[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=( pytest-{jupyter,tornasync} )
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Don't try (and fail) to fetch things from the internet with npm
+	# https://bugs.gentoo.org/820317
+	sed -i -e '/cmdclass=cmdclass/d' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}