dev-python/pycairo: version bump to 1.16.1

dev-python/pycairo/Manifest

@@ -1,2 +1,3 @@
 DIST pycairo-1.15.3.tar.gz 177056 BLAKE2B cba4a212c3537d5718a73742468444b01372902d86f88558cf63ab2ec1999dac036b349d84dff0bdcae5126998c5e921f05bab54b708a29ca2381b8d1371ac44 SHA512 1fc75d193eacb976f2e5a594aa07409a0f80ccb21921065c1794961143785eed48be1966d2d2d3e2d0428f9b4e956994dd851d21f3c3cb91fbc27b007a901ce8
 DIST pycairo-1.15.4.tar.gz 178436 BLAKE2B 23c5064f537b8d8be12bb64df375c1d5be8962f80adf2437115dde59c18c3755a693b0cb8b3bee248ce8c906f23acfa264f2da6e02770bc59d823beba1bc9e7b SHA512 7e785d23393a8d0c5aca9a4440eb64b0eca9a60c1a18b0dc8452edd6de9422c743d082530387bcbedd34d52377d0892ad395998e9467ba08e22c318684cbee34
+DIST pycairo-1.16.1.tar.gz 180516 BLAKE2B 0a144eb6f17bc6621b16e00ddd40784e16e5950667d57927ee238e76d4966e828d8da3d6983e09655d3eb2d3526dcb8a44da6c48e14268cd78e1d463e59b8779 SHA512 757870dd28d037d0af96308e2d1eb5d55ca2025aabda66031dc77790692e420b07802ccdbeefee430825553ed993830bc6f74de83b717e6fa876108f7b54e144

dev-python/pycairo/pycairo-1.16.1.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="https://www.cairographics.org/pycairo/ https://github.com/pygobject/pycairo"
+SRC_URI="https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test xcb"
+
+# Note: xpyb is used as the C header, not Python modules
+RDEPEND="
+	>=x11-libs/cairo-1.13.1[svg,xcb?]
+"
+DEPEND="${RDEPEND}
+	xcb? ( $(python_gen_cond_dep '>=x11-libs/xpyb-1.3' 'python2*') )
+	doc? ( dev-python/sphinx )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Fix pkgconfig path
+	sed -i -e "/libdir =/s:\"lib\":\"$(get_libdir)\":" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	local enable_xpyb
+	python_is_python3 || enable_xpyb=$(usex xcb "--enable-xpyb" "")
+
+	esetup.py build ${enable_xpyb}
+}
+
+python_compile_all() {
+	use doc && emake -C docs
+}
+
+python_test() {
+	local enable_xpyb
+	python_is_python3 || enable_xpyb=$(usex xcb "--enable-xpyb" "")
+
+	esetup.py test ${enable_xpyb}
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/. )
+
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}