From 04079abc1cd69793553f181bc5340da6235b565d Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Tue, 2 Jun 2026 15:07:41 -0400
Subject: [PATCH] x11-libs/libxkbcommon: Version bump to 1.13.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 x11-libs/libxkbcommon/Manifest                |  1 +
 .../libxkbcommon/libxkbcommon-1.13.2.ebuild   | 75 +++++++++++++++++++
 2 files changed, 76 insertions(+)
 create mode 100644 x11-libs/libxkbcommon/libxkbcommon-1.13.2.ebuild

diff --git a/x11-libs/libxkbcommon/Manifest b/x11-libs/libxkbcommon/Manifest
index b275aa367bcad..43d85b6177264 100644
--- a/x11-libs/libxkbcommon/Manifest
+++ b/x11-libs/libxkbcommon/Manifest
@@ -1 +1,2 @@
 DIST libxkbcommon-1.13.1.tar.gz 1234661 BLAKE2B ecad42f01fa6bac526f4e7bc6949bcd3b4c166360eef97c489ed543013a5489950956d551f043a42500c0857d0bb1d9b3f0b534293dcc85ada3c1a8cc8a611f2 SHA512 450c33fe26af6b847cf7516685d0df63c2ba0126887e27595c40fe80e4d0487009aa6cdf38ff1270d595c7900cbf3c11e7aa4f9cff80fa361742b5ebb10d83bd
+DIST libxkbcommon-1.13.2.tar.gz 1243485 BLAKE2B 98df853415ebb3f29521fc637e8db54730b666c42897b5e9bbc7177d2837e3303d5c16c08ef0b06cbbb17ba8e578e108546aabbded8452b393c35eef7dfb80e4 SHA512 261af9e02ad533bb6560e2711171812c7d92094db8b54eaa19b477ab68270e6d62b315e18d42527ca9c944e87f36f063d003d74aeb4829b21ecb96ab1b0c1ce7
diff --git a/x11-libs/libxkbcommon/libxkbcommon-1.13.2.ebuild b/x11-libs/libxkbcommon/libxkbcommon-1.13.2.ebuild
new file mode 100644
index 0000000000000..dd37a2582c478
--- /dev/null
+++ b/x11-libs/libxkbcommon/libxkbcommon-1.13.2.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = *9999* ]]; then
+	GIT_ECLASS="git-r3"
+	EGIT_REPO_URI="https://github.com/xkbcommon/${PN}"
+else
+	SRC_URI="https://github.com/xkbcommon/libxkbcommon/archive/refs/tags/xkbcommon-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+	S="${WORKDIR}/libxkbcommon-xkbcommon-${PV}"
+fi
+
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit bash-completion-r1 meson-multilib ${GIT_ECLASS} python-any-r1 virtualx
+
+DESCRIPTION="Keymap handling library for toolkits and window systems"
+HOMEPAGE="https://xkbcommon.org/ https://github.com/xkbcommon/libxkbcommon/"
+LICENSE="MIT"
+SLOT="0"
+
+IUSE="doc static-libs test tools wayland X"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	>=sys-devel/bison-3.6
+	doc? ( app-text/doxygen[dot] )
+	test? (
+		${PYTHON_DEPS}
+		x11-apps/setxkbmap
+	)
+	tools? ( wayland? ( dev-util/wayland-scanner ) )
+"
+RDEPEND="
+	X? ( >=x11-libs/libxcb-1.10:=[${MULTILIB_USEDEP}] )
+	tools? ( wayland? ( >=dev-libs/wayland-1.2.0[${MULTILIB_USEDEP}] ) )
+	dev-libs/libxml2:=[${MULTILIB_USEDEP}]
+	x11-misc/compose-tables
+	x11-misc/xkeyboard-config
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	tools? ( wayland? ( >=dev-libs/wayland-protocols-1.15 ) )
+"
+
+pkg_setup() {
+	if use test; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_library="$(usex static-libs both shared)"
+		-Dxkb-config-root="${EPREFIX}/usr/share/X11/xkb"
+		-Dbash-completion-path="$(get_bashcompdir)"
+		$(meson_native_use_bool tools enable-tools)
+		$(meson_use X enable-x11)
+		$(meson_native_use_bool doc enable-docs)
+		$(meson_use wayland enable-wayland)
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	virtx meson_src_test
+}
+
+multilib_src_install_all() {
+	if use doc; then
+		mv "${ED}"/usr/share/doc/{${PN},${P}} || die
+	fi
+}