diff --git a/x11-misc/xkeyboard-config/Manifest b/x11-misc/xkeyboard-config/Manifest
index 4e6c10ea7fd2a..a9e0b3cdbdbdd 100644
--- a/x11-misc/xkeyboard-config/Manifest
+++ b/x11-misc/xkeyboard-config/Manifest
@@ -1 +1,2 @@
 DIST xkeyboard-config-2.44.tar.xz 906060 BLAKE2B 6abb485ef5c9cb1292afaed22ac72026dc22c0a08c3bf04ca29f8dd61d68cbf06e511fe095628a0ab6dec7766374318c4b5bddeb2c4da8a8a692bbbbf4b4e83b SHA512 1bd6c594c132d262863e9911cfe4e70936c82a87c118b302d032cc900767653abd6db3ee5bc8220dafa8cf65aba15e3ceae9cbd88c318dd404d3c432c8ed9c00
+DIST xkeyboard-config-2.45.tar.xz 916148 BLAKE2B 5c322500878f17ac5e30464966d448c176c1420bd187c419b47121ba596ea47fe3b3950b39bd25683e76573edb49299c2b650a23d1e2345df3edbb018c730c18 SHA512 1b82ced3e2a6386d40f9bac3735a72986b9f7387c356a706373724858a920e33ae0a9bd777a388dfdee43efc4dd6c2aa172d4b923fa2ca32e9a619f410437a7c
diff --git a/x11-misc/xkeyboard-config/xkeyboard-config-2.45.ebuild b/x11-misc/xkeyboard-config/xkeyboard-config-2.45.ebuild
new file mode 100644
index 0000000000000..4ebef64ae30a7
--- /dev/null
+++ b/x11-misc/xkeyboard-config/xkeyboard-config-2.45.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit meson python-any-r1
+
+DESCRIPTION="X keyboard configuration database"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/XKeyboardConfig/ https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config.git"
+	inherit git-r3
+else
+	SRC_URI="https://www.x.org/releases/individual/data/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-lang/perl
+	dev-libs/libxslt
+	sys-devel/gettext
+	${PYTHON_DEPS}
+	test? (
+		x11-apps/xkbcomp
+		x11-libs/libxkbcommon
+		$(python_gen_any_dep '
+			dev-python/pycountry[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	use test || return 0
+	python_has_version \
+		"dev-python/pycountry[${PYTHON_USEDEP}]" \
+		"dev-python/pytest-xdist[${PYTHON_USEDEP}]" \
+		"dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	eapply_user
+
+	# Remove pytest timeout
+	sed -i -e "/test('pytest'/,/)$/ { s/timeout: [0-9]*/timeout: 0/ }" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dxkb-base="${EPREFIX}/usr/share/X11/xkb"
+		-Dcompat-rules=true
+	)
+	meson_src_configure
+}