dev-libs/girara: add USE=X to avoid automagic

Inspired by one of Eli's commits that solved
957789 series od bugs.

Also minor ebuild improvements:
- remove -a from emesonargs declaration
  - functionality is the same and that style is less common
- use . instead of * for docs to use less paths

Signed-off-by: Filip Kobierski <fkobi@pm.me>
Part-of: https://github.com/gentoo/gentoo/pull/41617
Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/girara/girara-0.4.5-r1.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic meson
+
+DESCRIPTION="UI library that focuses on simplicity and minimalism"
+HOMEPAGE="https://pwmt.org/projects/girara/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwmt/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	SRC_URI="https://github.com/pwmt/girara/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="ZLIB"
+SLOT="0/$(ver_cut 2-3)"
+IUSE="doc test X"
+RESTRICT="!test? ( test )"
+
+# REVIEW: are all those really needed?
+RDEPEND="
+	app-accessibility/at-spi2-core
+	>=dev-libs/glib-2.72:2
+	dev-libs/json-glib:=
+	media-libs/harfbuzz:=
+	x11-libs/cairo[glib]
+	x11-libs/gdk-pixbuf
+	>=x11-libs/gtk+-3.24:3[X?]
+	x11-libs/pango
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		x11-base/xorg-proto
+		x11-libs/gtk+:3[X]
+		x11-misc/xvfb-run
+	)
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+"
+
+DOCS=( AUTHORS README.md )
+
+src_configure() {
+	# defang automagic dependencies
+	# Currently only needed for X11-specific workarounds
+	use X || append-flags -DGENTOO_GTK_HIDE_X11
+
+	local emesonargs=(
+		-Djson=enabled
+		$(meson_feature doc docs)
+		$(meson_feature test tests)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+	use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/html/. ) # BUILD_DIR is set by meson_src_compile
+}

dev-libs/girara/girara-9999.ebuild

@@ -3,7 +3,7 @@
 
 EAPI=8
 
-inherit meson
+inherit flag-o-matic meson
 
 DESCRIPTION="UI library that focuses on simplicity and minimalism"
 HOMEPAGE="https://pwmt.org/projects/girara/"
@@ -19,7 +19,7 @@ fi
 
 LICENSE="ZLIB"
 SLOT="0/9999"
-IUSE="doc test"
+IUSE="doc test X"
 RESTRICT="!test? ( test )"
 
 # REVIEW: are all those really needed?
@@ -30,7 +30,7 @@ RDEPEND="
 	media-libs/harfbuzz:=
 	x11-libs/cairo[glib]
 	x11-libs/gdk-pixbuf
-	>=x11-libs/gtk+-3.24:3
+	>=x11-libs/gtk+-3.24:3[X?]
 	x11-libs/pango
 "
 DEPEND="
@@ -50,7 +50,11 @@ BDEPEND="
 DOCS=( AUTHORS README.md )
 
 src_configure() {
-	local -a emesonargs=(
+	# defang automagic dependencies
+	# Currently only needed for X11-specific workarounds
+	use X || append-flags -DGENTOO_GTK_HIDE_X11
+
+	local emesonargs=(
 		-Djson=enabled
 		$(meson_feature doc docs)
 		$(meson_feature test tests)
@@ -60,5 +64,5 @@ src_configure() {
 
 src_compile() {
 	meson_src_compile
-	use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/html/* ) # BUILD_DIR is set by meson_src_compile
+	use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/html/. ) # BUILD_DIR is set by meson_src_compile
 }