dev-python/html2text: bump to 2019.9.26, support Python 3.7

* Python 2 is no longer supported.
* chardet and feedparser are no longer required.
* pytest is now required to run tests.
* fetch source from PyPI instead of GitHub.

Closes: https://bugs.gentoo.org/694524
Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

dev-python/html2text/html2text-2019.9.26.ebuild

@@ -0,0 +1,35 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy3 python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Turn HTML into equivalent Markdown-structured text"
+HOMEPAGE="https://github.com/Alir3z4/html2text https://pypi.org/project/html2text/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="test"
+
+# pkg_resources is used for entry points
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+DOCS=( AUTHORS.rst ChangeLog.rst README.md )
+
+python_prepare_all() {
+	# naming conflict with app-text/html2text, bug 421647
+	sed -i 's/html2text = html2text.cli:main/py\0/' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pytest -vv || die "tests failed with ${EPYTHON}"
+}