diff --git a/app-arch/sasquatch/Manifest b/app-arch/sasquatch/Manifest
new file mode 100644
index 0000000000000..ba92f7035cab8
--- /dev/null
+++ b/app-arch/sasquatch/Manifest
@@ -0,0 +1 @@
+DIST sasquatch-4.5.1.4.tar.gz 498093 BLAKE2B 3b5d2175417fe47921581c7f1ad95f7ffb04507e1b622d1f8758ca71ea3047d689e0b1831765667f412ad29b6415ffc709423e036c188820fe31b8806629230f SHA512 94ae869f9d9a832b93e0d464983939a8fe2fb8e8b2ef39d5c3c628db5bd98dd93af6158117dfc9abbd0b9be7ba3967c06e0f636e3dc7af4dba1f6f6d290bcaf7
diff --git a/app-arch/sasquatch/metadata.xml b/app-arch/sasquatch/metadata.xml
new file mode 100644
index 0000000000000..c2e1efa76c7fc
--- /dev/null
+++ b/app-arch/sasquatch/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>davidroman96@gmail.com</email>
+		<name>David Roman</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">onekey-sec/sasquatch</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/app-arch/sasquatch/sasquatch-4.5.1.4.ebuild b/app-arch/sasquatch/sasquatch-4.5.1.4.ebuild
new file mode 100644
index 0000000000000..12c84b2061646
--- /dev/null
+++ b/app-arch/sasquatch/sasquatch-4.5.1.4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+MY_PV="$(ver_rs 3 '-')"
+MY_P="${PN}-v${MY_PV}"
+DESCRIPTION="An extended version of sasquashfs-tools"
+HOMEPAGE="https://github.com/onekey-sec/sasquatch"
+SRC_URI="https://github.com/onekey-sec/sasquatch/archive/refs/tags/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+S="${WORKDIR}/${PN}-${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug lz4 lzma lzo xattr zstd"
+
+DEPEND="
+	sys-libs/zlib
+	lz4? ( app-arch/lz4 )
+	lzma? ( app-arch/xz-utils )
+	lzo? ( dev-libs/lzo )
+	xattr? ( sys-apps/attr )
+	zstd? ( app-arch/zstd )
+"
+RDEPEND=${DEPEND}
+
+use10() {
+	usex "${1}" 1 0
+}
+
+src_compile() {
+	# set up make command line variables in EMAKE_SQUASHFS_CONF
+	local opts=(
+		LZMA_XZ_SUPPORT=$(use10 lzma)
+		LZO_SUPPORT=$(use10 lzo)
+		LZ4_SUPPORT=$(use10 lz4)
+		XATTR_SUPPORT=$(use10 xattr)
+		XZ_SUPPORT=$(use10 lzma)
+		ZSTD_SUPPORT=$(use10 zstd)
+	)
+
+	tc-export CC
+	use debug && append-cppflags -DSQUASHFS_TRACE
+	emake "${opts[@]}" -C squashfs-tools
+}
+
+src_install() {
+	dobin squashfs-tools/sasquatch
+	dodoc ACKNOWLEDGEMENTS CHANGES README*
+	doman manpages/*.1
+}